Inverting a function via CLP(FD) in pure Prolog - while-loop

Question

Lets take this function:
function gcd(a, b)
while a ≠ b
if a > b
a := a − b
else
b := b − a
return a
How would we code gcd/3 in pure Prolog, so that it can be inverted. The Prolog predicate should for example compute gcd(2,3)=1. But if we would ask what are the a, b such that gcd(a,b)=1, we would also get by the same Prolog predicate:
/* one while iteration */
2, 1
1, 2
/* two while iterations */
3, 1
2, 3
3, 2
1, 3
/* Etc... */
Prolog seems to be especially suited since it can enumerate solutions.

Answer 1

I first tried to literally translate the GCD function
into a Prolog code. The first clause is for when a ≠ b is false,
which means we can terminate the function. Otherwise we
recurse into the two cases:
euclid(A,A,A).
euclid(A,B,R) :- A #< B, C #= B-A, euclid(A,C,R).
euclid(A,B,R) :- A #> B, C #= A-B, euclid(C,B,R).
We can test, seems to work fine, except it has choice points.
But the choice points are kind of the price we have to pay for
using CLP(FD) and programming pure Prolog without cut:
?- euclid(17,13,X).
X = 1 ;
No
But using euclid/3 for enumeration isn't very satisfactory,
the result is only one execution branch of the GCD function:
?- euclid(A,B,1).
A = 1,
B = 1 ;
A = 1,
B = 2 ;
A = 1,
B = 3 ;
A = 1,
B = 4 ;
Now we can do the following and encode a path P through the GCD
function by a binary number. When we terminate the path will be P=1.
Otherwise we use the lower bit of P to encode which of the two remaining
clauses of the GCD were chosen:
euclid(A,A,1,A).
euclid(A,B,P,R) :- A #< B, C #= B-A, P #= 2*Q, Q #> 0, euclid(A,C,Q,R).
euclid(A,B,P,R) :- A #> B, C #= A-B, P #= 2*Q+1, Q #> 0, euclid(C,B,Q,R).
The resulting Prolog predicate is indeed bidirectional:
?- euclid(17,13,P,X).
P = 241,
X = 1 ;
No
?- euclid(A,B,241,1).
A = 17,
B = 13 ;
No
We can also use it to arbitrarily enumerate, although only with
the help of between/3 and maybe not the most efficient, but it wurks:
?- between(1,7,P), euclid(A,B,P,1), write(B/A), nl, fail; true.
1/1
2/1
1/2
3/1
2/3
3/2
1/3
Yes
Edit 04.02.2021:
Oh, interesting, this works also. But the result is differently ordered:
?- P #< 8, euclid(A,B,P,1), write(B/A), nl, fail; true.
1/1
2/1
3/1
3/2
1/2
2/3
1/3
true.

Answer 2

This solution uses an argument to keep track of the current tier of the loop:
gcd(A, B, G):-
gcd(_, A, B, G).
gcd(Tier, A, B, G):-
Tier1 #= Tier - 1,
Tier1 #>= 0,
zcompare(Order, A, B),
gcd(Order, Tier1, A, B, G).
gcd(=, 0, G, G, G).
gcd(>, Tier, A, B, G):-
A1 #= A - B,
gcd(Tier, A1, B, G).
gcd(<, Tier, A, B, G):-
B1 #= B - A,
gcd(Tier, A, B1, G).
So when you want to get a tiered enumeration you my write:
?- between(1,3,Tier), gcd(Tier, A,B,1), write(B/A), nl, fail; true.
1/1
1/2
2/1
1/3
2/3
3/2
3/1
true.