How do I resolve SQL ConnectionString error? - vb.net

Question

I have a Form with a DataGridView and a Button. They are interacting with an Access (.mdb) database. When the Button is clicked, I want it to update the data in the Table.
I get the following error:
Value of type 'OleDbConnection' cannot be converted to
'SqlConnection'.
My code:
Imports System.Data.OleDb
Imports System.Data.SqlClient
Public Class Form1
Public conn As New OleDbConnection
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim DS As New DataSet
Dim DT As New DataTable
DS.Tables.Add(DT)
Dim objConn As String = "Provider=Microsoft.JET.OLEDB.4.0; Data Source = Swiftest.mdb"
conn.ConnectionString = objConn
Dim objDA As New OleDb.OleDbDataAdapter("SELECT * FROM tblOptions", conn)
objDA.Fill(DT)
DataGridView1.DataSource = DT.DefaultView
End Sub
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim SqlQuery As String = "'UPDATE tblOptions Set fldShow = '1' WHERE fldID = '13'"
conn.Open()
Dim com As New SqlCommand(SqlQuery, conn)
End Sub
End Class
Thanks for reading

Answer 1

Several of the database objects available is ADO.net have .Dispose methods. If an object has a dispose method it may be using unmanaged resources (resources outside the .net framework). These objects need to release these resources and they do this in there dispose methods. Fortunately the .net languages provide Using...End Using blocks which will guarentee that .Dispose is called even if there is an error.
In view of this create your database objects in the Sub or Function where they are used so they can be enclosed in Using blocks. Note the comma at the end of the connection Using line. This indicates that the object on the next line (the command) is included in the same Using block.
In your Form.Load event, you never used the adapter or the dataset. Just load the datatable.
Open the connection at the last possible moment, directly before the .Execute... and close immediately with the End Using. In your Button1.Click event you open a connection, never execute anything and never close it.
In your update command you provide literals as String. Normally, an ID field is an Integer. Check you database for the datatype of the fields. If you want to provide values that are not literals use parameters.
Private connStr As String = "Provider=Microsoft.JET.OLEDB.4.0; Data Source = Swiftest.mdb"
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim DT As New DataTable
Using conn As New OleDbConnection(connStr),
cmd As New OleDbCommand("SELECT * FROM tblOptions", conn)
conn.Open()
Using reader = cmd.ExecuteReader
DT.Load(reader)
End Using
End Using
DataGridView1.DataSource = DT.DefaultView
End Sub
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Using conn As New OleDbConnection(connStr),
cmd As New OleDbCommand("UPDATE tblOptions Set fldShow = '1' WHERE fldID = '13'", conn)
conn.Open()
cmd.ExecuteNonQuery()
End Using
End Sub