Assign to one object cause change also in another object - vba

Question

Following this code, I got a strange behavior. assigning to one range object cause change also in another object
Sub test()
Dim pRange1 As Word.Range
Dim pRange2 As Word.Range
' ActiveDocument.Range => String "12"
Set pRange1 = ActiveDocument.Range.Characters(1) 'pRange1 =1
'
Set pRange2 = ActiveDocument.Range.Characters(2) 'pRange1 =2
pRange1.Text = "3" ' pRange1=3 and pRange2=33 ????!!!
End Sub
Why after assignment of
pRange1.Text = "3"
pRange1 object also changed?

Answer 1

I think this is what's happening (I am open to corrections):
The first thing to note is that Range.Characters(1) is the same as Range(0, 1) which means the range starting at character with index 0 up to but not including character with index 1
It appears to me that setting Range.Text = "ab" happens in two stages. First the range is deleted (Range.Delete) and then the text "ab" is assigned to the range.
The following code should explain the behaviour:
Sub Test()
Dim r1 As Range
Dim r2 As Range
Dim r3 As Range
With ActiveDocument
.Range = "abc"
Set r1 = .Range(0, 1) '* similar to .Characters(1)
Set r2 = .Range(1, 2) '* similar to .Characters(2)
Set r3 = .Range(2, 3) '* similar to .Characters(3)
'* At this point r1, r2 and r3 are distinct ranges
Debug.Print "Before:"
Debug.Print "-------"
Debug.Print "r1: " & r1 & vbTab & "start index: " & r1.Start & vbTab & "end index: " & r1.End
Debug.Print "r2: " & r2 & vbTab & "start index: " & r2.Start & vbTab & "end index: " & r2.End
Debug.Print "r3: " & r3 & vbTab & "start index: " & r3.Start & vbTab & "end index: " & r3.End
r1.Delete
'* At this point r1 is a subset of r2. Therefore, changing
'* r1 will change r2. r3 is a distinct range
Debug.Print
Debug.Print "After Deletion:"
Debug.Print "---------------"
Debug.Print "r1: " & r1 & vbTab & "start index: " & r1.Start & vbTab & "end index: " & r1.End
Debug.Print "r2: " & r2 & vbTab & "start index: " & r2.Start & vbTab & "end index: " & r2.End
Debug.Print "r3: " & r3 & vbTab & "start index: " & r3.Start & vbTab & "end index: " & r3.End
r1.Text = "z"
'* At this point r1 is still a subset of r2. r3 is a distinct range
Debug.Print
Debug.Print "After Adding Text:"
Debug.Print "------------------"
Debug.Print "r1: " & r1 & vbTab & "start index: " & r1.Start & vbTab & "end index: " & r1.End
Debug.Print "r2: " & r2 & vbTab & "start index: " & r2.Start & vbTab & "end index: " & r2.End
Debug.Print "r3: " & r3 & vbTab & "start index: " & r3.Start & vbTab & "end index: " & r3.End
End With
End Sub
The output is:
Before:
-------
r1: a start index: 0 end index: 1
r2: b start index: 1 end index: 2
r3: c start index: 2 end index: 3
After Deletion:
---------------
r1: start index: 0 end index: 0
r2: b start index: 0 end index: 1
r3: c start index: 1 end index: 2
After Adding Text:
------------------
r1: z start index: 0 end index: 1
r2: zb start index: 0 end index: 2
r3: c start index: 2 end index: 3
Edit: (following comment below)
Here's a not-so-pretty workaround. The main idea is to insert the new text and then delete the old text. This way the next range r2 doesn't collapse into the current range r1 (i.e. distinct ranges remain separate).
Sub Test2()
Dim r1 As Range
Dim r2 As Range
Dim r3 As Range
With ActiveDocument
.Range = "abc"
Set r1 = .Characters(1)
Set r2 = .Characters(2)
Set r3 = .Characters(3)
Debug.Print "Before:"
Debug.Print "-------"
Debug.Print "r1: " & r1 & vbTab & "start index: " & r1.Start & vbTab & "end index: " & r1.End
Debug.Print "r2: " & r2 & vbTab & "start index: " & r2.Start & vbTab & "end index: " & r2.End
Debug.Print "r3: " & r3 & vbTab & "start index: " & r3.Start & vbTab & "end index: " & r3.End
ReplaceRangeText r1, "z"
Debug.Print
Debug.Print "After:"
Debug.Print "------"
Debug.Print "r1: " & r1 & vbTab & "start index: " & r1.Start & vbTab & "end index: " & r1.End
Debug.Print "r2: " & r2 & vbTab & "start index: " & r2.Start & vbTab & "end index: " & r2.End
Debug.Print "r3: " & r3 & vbTab & "start index: " & r3.Start & vbTab & "end index: " & r3.End
End With
End Sub
Function ReplaceRangeText(rng As Range, sNewText As String) As Range
Dim sOldText As String
With rng
sOldText = .Text
.InsertBefore sNewText
.Document.Range(.Start + Len(sNewText), .End).Delete
End With
Set ReplaceRangeText = rng
End Function
The output is:
Before:
-------
r1: a start index: 0 end index: 1
r2: b start index: 1 end index: 2
r3: c start index: 2 end index: 3
After:
------
r1: z start index: 0 end index: 1
r2: b start index: 1 end index: 2
r3: c start index: 2 end index: 3