Mutually excluding checkboxes in Word table - vba

Question

I created a Word Document (Word 2016) that, by clicking a button, generates a Table with predefined text and formatting.
Column1
Column2
Column3
QUESTION (Y/N)
YES_Checkbox
No_Checkbox
Row number 8 (shown above) contains a YES/NO question; to manage that, I inserted two Checkboxes (one in Column2, the other in Column3) using the following syntax:
For ii = 2 To 3
Set rng = mytable.Cell(8, ii).Range
rng.Select
With Selection
.Collapse Direction:=wdCollapseStart
.Range.ContentControls.Add wdContentControlCheckBox
.MoveRight Unit:=wdCharacter, Count:=2
End With
Next ii
My idea is to have mutually exclusive checkboxes: that means, if User selects "YES" the "NO" is automatically deselected (and vice-versa). To do so, I created a Sub within the main button script. It checks for the checkbox value and then tries to 'tick it' (on un-tick it) using the following code (not yet completed):
Sub Check_YES_Not(tblNew)
Dim thisCell As Range
check1 = mytable.Cell(8, 2).Range.ContentControls(1).Checked
check2 = mytable.Cell(8, 3).Range.ContentControls(1).Checked
'If condition to be added
check1 = True 'This is how I am trying to modify the checkbox, but it is not working
'ElseIf add other conditions...
'Msgbox "to be completed..."
'End If
End Sub
Code runs and creates the table correctly, but the checkbox scripts is not behaving as I wish. Could someone please tell me what I am doing wrong and how I could make it work? Thank you very much.
UPDATE
This is how I solved it. There are still minor concerns (e.g. if I click "Yes", I need to select another cell before clicking "No", otherwise the control is not able to work correctly). Apart from this, many thanks to #macropod and Timothy for their kind support.
In order to allow the User to create additional table, I created a Public counter that is increased at each added table. It is not an elegant solution, but it works for now. The initial table has a different tag (I did not include it here).
Private Sub Document_ContentControlOnExit(ByVal oCC As ContentControl, Cancel As Boolean)
Dim collCCs As ContentControls
Dim oCCTarget As ContentControl
Dim ii As Integer
For ii = 1 To 500 'Additional tables
If Not IsEmpty(ActiveDocument.SelectContentControlsByTag("NO" + Str(ii))) Then
Select Case oCC.Tag
Case "YES" + Str(ii)
Set collCCs = ActiveDocument.SelectContentControlsByTag("NO" + Str(ii))
For Each oCCTarget In collCCs
If oCCTarget.Checked = True Then
oCCTarget.Checked = False
Exit For
End If
Next
Case "NO" + Str(ii)
Set collCCs = ActiveDocument.SelectContentControlsByTag("YES" + Str(ii))
For Each oCCTarget In collCCs
If oCCTarget.Checked = True Then
oCCTarget.Checked = False
Exit For
End If
Next
End Select
End If
Next ii

Answer 1

Your code isn't working as you are only setting the value of a variable, not the checked status of the checkbox. The simplest way of achieving your desired result is to set the checked status of one checkbox to the opposite of the other, like this:
mytable.Cell(8, 2).Range.ContentControls(1).Checked = Not mytable.Cell(8, 3).Range.ContentControls(1).Checked
Also your code to insert the content controls can be simplified to:
For ii = 2 To 3
mytable.Cell(8, ii).Range.ContentControls.Add wdContentControlCheckBox
Next ii
There is rarely any need to select anything when working with Word.
Finally, you appear not to be forcing variable declaration. This can lead to avoidable errors in your code. Just add Option Explicit at the top of every code module. This will prevent your code from compiling when you have undeclared variables. To add this automatically to new modules open the VBE and go to Tools | Options. In the Options dialog ensure that "Require Variable Declaration" is checked.