CMake: Ask user permission to install dependencies - cmake

Question

Many build systems (such as make) sometimes prompt the user to confirm his intention if large dependencies must be downloaded and installed from the internet to continue with the build process.
What is the best way to achieve this from CMake?
My example application. I'm adapting a CMakeLists.txt file that installs Google Test framework if it isn't found. How should I modify this to ask the user for permission before installing it?
Alternatively, perhaps this is not possible/standard and I should instead just require the user to pass a variable definition when calling CMake, to assert his consent to the download?
# Quote from:
# https://github.com/pabloariasal/modern-cmake-sample/blob/master/libjsonutils/test/CMakeLists.txt
# Commit hash 0c8272b621f2bfd819c406b575517fdeb05a38a7
# ---------------------- Below original contents. ------------------------------
# see /opt/local/share/cmake-3.16/Modules/FindGTest.cmake
find_package(GTest QUIET)
# NOTE: the upper case GTEST! CK
if(NOT GTEST_FOUND)
# Download and unpack googletest at configure time
# but only if needed! CK
configure_file(${CMAKE_SOURCE_DIR}/cmake/GoogleTest-CMakeLists.txt.in
${CMAKE_BINARY_DIR}/googletest-download/CMakeLists.txt)
execute_process(COMMAND ${CMAKE_COMMAND} -G "${CMAKE_GENERATOR}" .
RESULT_VARIABLE result
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/googletest-download)
if(result)
message(FATAL_ERROR "CMake step for googletest failed: ${result}")
endif()
execute_process(COMMAND ${CMAKE_COMMAND} --build .
RESULT_VARIABLE result
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}/googletest-download)
if(result)
message(FATAL_ERROR "Build step for googletest failed: ${result}")
endif()
# Add googletest directly to our build. This defines
# the gtest and gtest_main targets.
add_subdirectory(${CMAKE_BINARY_DIR}/googletest-src
${CMAKE_BINARY_DIR}/googletest-build
EXCLUDE_FROM_ALL)
endif()
# Now simply link against gtest as needed. Eg
add_executable(json_utils_test src/main.cpp)
target_compile_features(json_utils_test PRIVATE cxx_auto_type)
target_link_libraries(json_utils_test gtest_main JSONUtils::jsonutils)
add_test(NAME json_utils_test
COMMAND json_utils_test)

Answer 1

Passing a variable to CMake is a proper way for specify an user decision.
Asking a user for confirm some default decision looks nice... but I fear CMake has no ready-to-use tools for that. Note, that configuration of the project could be requested both in shell/terminal (via cmake executable) and from CMake GUI, which is not connected with the user input.
Instead of asking the user for confirmation during the configuration process, you may fail configuration (e.g. with message(FATAL_ERROR)). But ship this fail with the message describing the variable a user needs to set.
# Variable-option for a user.
option(DOWNLOAD_GTEST "Whether GTest is needed to be downloaded" OFF)
if (DOWNLOAD_GTEST)
# User explicitly requests to download gtest.
# Do not try 'find_package' at all.
#
# Download and unpack googletest at configure time
configure_file(${CMAKE_SOURCE_DIR}/cmake/GoogleTest-CMakeLists.txt.in
${CMAKE_BINARY_DIR}/googletest-download/CMakeLists.txt)
...
else()
# GTest download hasn't been requested.
# Try to find installed variant.
find_package(GTest)
if(NOT GTEST_FOUND)
# No installed variant has been found.
# Fail configuration with a notion about 'DOWNLOAD_GTEST' variable.
message(FATAL_ERROR "GTest has not been found. If you want to automatically download it, please set variable 'DOWNLOAD_GTEST': cmake -DDOWNLOAD_GTEST=ON")
endif()
endif()
With that CMakeLists.txt, if a user doesn't explicitly set variable DOWNLOAD_GTEST, then it is set to OFF. In that case GTest is searched with find_package. If search fails, then configuration process fails too but with a suggestion to set the variable.
If a user reruns cmake with the variable DOWNLOAD_GTEST set to ON, then GTest will be downloaded without extra messages.