Microsoft Word: Select and GoTo InlineShape - vba

Question

A macro in my Word document goes through all the graphs (inlineshapes) and updates links and values. At the moment the document freezes for the whole process behind a "Please wait" form dialog. Ideally I'd have the code move throughout the document to show the user that stuff is actually happening.
How can I select and GoTo the current inlineshape within my loop below?
Private Sub UpdateFields()
PleaseWait.bar.Width = 0
PleaseWait.Show
' This routine sets the new path for external links, pointing them to the current folder.
Dim Rng As Range, Fld As Field, Shp As Shape, iShp As InlineShape, i As Long
Dim no_of_steps As Integer
Dim single_step_width As Integer
no_of_steps = 0
With ThisDocument
' Create progress bar
' a) Count total number of steps
For Each Rng In .StoryRanges
For Each iShp In Rng.InlineShapes
no_of_steps = no_of_steps + 1
Next iShp
Next Rng
' b) Divide full width of progress frame by number of steps
single_step_width = PleaseWait.frame.Width \ no_of_steps
' Go through all story ranges in the document.
For Each Rng In .StoryRanges
' Go through the inlineshapes in the story range.
For Each iShp In Rng.InlineShapes
With iShp
' Skip over inlineshapes that don't have links to external files.
If Not .LinkFormat Is Nothing Then
With .LinkFormat
' Skip links already set to current folder
If Not .SourceFullName = ThisDocument.Path & "\datagrunnlag.xlsm" Then
' Replace the link to the external file
.SourceFullName = ThisDocument.Path & "\datagrunnlag.xlsm"
On Error Resume Next
.AutoUpdate = False
.Update
On Error GoTo 0
End If
End With
End If
' Update progress bar with completed step
PleaseWait.bar.Width = PleaseWait.bar.Width + single_step_width
DoEvents
End With
Next iShp
Next Rng
End With
End Sub
Edit 05.12.2020: added all code within the sub. ScreenUpdating = False and True are being set by separate subs for MacroEntry and MacroExit.

Answer 1

That would be a really bad idea. Using the Selection object will just slow the operation down even more, and leave the user cursing you.
As you already appear to have a progress indicator, you are doing all that you can to keep the user informed.
Anything that involves scrolling the document makes your code run more slowly, so the best you can do is ensure your code completes in as short a time as possible. This includes avoiding use of the Selection object and turning off ScreenUpdating.