Conditional Formatting in MS Word using VBA - vba

Question

Good day,
I'm trying to make an efficient conditional formatting work in Microsoft Word with an VBA, that will be very similar to the formatting known from Excel.
My current solution
I have a 4th column with an IF statement in a field that checks if the value in Column 2 is less equal or higher than in Column 3, combined with this VBA for conditional formatting:
Sub UBC()
color "No", wdRed
color "Yes", wdBrightGreen
End Sub
Function color(text As String, backgroundColor As WdColorIndex)
Dim r As Word.Range
Set r = ActiveDocument.Content
With r.Find
Do While .Execute(findText:=text, MatchWholeWord:=True, Forward:=True) = True
If r.Tables.Count > 0 Then
If r.Cells(1).ColumnIndex = 4 Then
r.Cells(1).Shading.BackgroundPatternColorIndex = backgroundColor
End If
End If
Loop
End With
End Function
The result I want to achieve
I want to eliminate the 4th column and use the VBA to do the check what's now handled by the IF statement. On top of that, I would also like to use RGB or HEX color codes instead of the wdColorIndex library.
Can somebody help me out modifying the current code?

Answer 1

Try this
Sub Tester()
Dim tbl As Table, rw As Row, v1, v2
Set tbl = ActiveDocument.Tables(1)
For Each rw In tbl.Rows
v1 = CellValue(rw.Cells(2))
v2 = CellValue(rw.Cells(3))
If IsNumeric(v1) And IsNumeric(v2) Then
v1 = CDbl(v1)
v2 = CDbl(v2)
Debug.Print v1, v2
rw.Cells(2).Shading.BackgroundPatternColor = _
IIf(v1 <= v2, RGB(100, 250, 100), RGB(250, 100, 100))
End If
Next rw
End Sub
Function CellValue(c As Cell)
Dim rv
rv = c.Range.Text
CellValue = Left(rv, Len(rv) - 2) 'remove "end of cell" marker
End Function