system.net.mail.attachments add error "Sorry something went wrong... " - vb.net

Question

I'm using VB.NET and creating a new Mail outlook item using Microsoft.Interop.Outlook ver#15.
I can create an Email object and set the Subject, Body, ToAddress, ccAddress, etc. just fine and display the new Email.
I am having issues when I try and add a .pdf file via file path string to Attachments using the .Add method. Get an error "Sorry something went wrong.. " I have moved the file into different folders locally and same error.
Dim oApp As Outlook.Application = New Outlook.Application
Dim mailItem As Outlook.MailItem = oApp.CreateItem(Outlook.OlItemType.olMailItem)
mailItem.Subject = _sSubject
mailItem.To = sToAddress
mailItem.CC = sCCAddress
mailItem.Body = sBody
''Commented out for now Until I can figure out error!!
For Each _File As String In sAttachList
Dim _AttachObject As New System.Net.Mail.Attachment(_File)
mailItem.Attachments.Add(_AttachObject)
Next
mailItem.Importance = Outlook.OlImportance.olImportanceNormal
mailItem.Display(True)
mailItem = Nothing
oApp = Nothing

Answer 1

I think, this line is the problem:
Dim _AttachObject As New System.Net.Mail.Attachment(_File)
Why not just add the absolute file paths? So this one should do it:
For Each _File As String In sAttachList
mailItem.Attachments.Add(_File)
Next
I use this functions:
Private Function Correct(Value As String) As String
If Value = "" Then Return Value
Return Value.Trim.Replace(",", ";").Replace(" ", "")
End Function
Private Sub AddAttachments(ByRef Mail As Outlook.MailItem, Attachments As String())
If Attachments Is Nothing OrElse Attachments.Count = 0 Then Return
For Each Attachment As String In Attachments
Mail.Attachments.Add(Attachment)
Next
End Sub
Public Sub SendMail(Receiver As String,
Subject As String,
Body As String,
Optional CC As String = "",
Optional BCC As String = "",
Optional Attachments As String() = Nothing)
Receiver = Correct(Receiver)
If Receiver = "" Then Return
Dim Mail As Outlook.MailItem = CType(OUT.CreateItem(Outlook.OlItemType.olMailItem), Outlook.MailItem)
With Mail
.To = Receiver
.Subject = Subject.Trim
.Body = Body.Trim
.CC = Correct(CC)
.BCC = Correct(BCC)
AddAttachments(Mail, Attachments)
If MyAccount IsNot Nothing Then .SendUsingAccount = MyAccount
If MySentFolder IsNot Nothing Then .SaveSentMessageFolder = MySentFolder
.Send()
End With
Mail = Nothing
End Sub
These are functions in a Outlook class, so some objects need explanation:
OUT is an openend Outlook.Application object
MyAccount is an Outlook.Account object. You can use it to send the mail with another account than the default
MySentFolder is an Outlook.Folder object. You can use it, if you want to store the sent mail in another folder than the default sent folder.
Surely you can omit these two lines in the code.