Send excel table as an attachment - vba

Question

Need your help.
I have an excel sheet of item master with stock availability and store email address are in heralding cells vertically & under the email address there are Y & N mapping done against entire style code in the in the item master.
I am looking for a VBA code that should filter database one by one for the email address mentioned in the heading cells and copy table where Y found and send the table as an attachment.
Subject would be "Updated SOH". Kindly refer database sample mentioned below.

Answer 1

I use a macro for sending emails all the time, here is the unedited code:
Sub SendEmail(Optional ToAddresses As String, Optional CcAddresses As String, _
Optional BccAddresses As String, Optional Subject As String, _
Optional Body As String, Optional AttachFiles As Variant = False, Optional AutoSend As Boolean = False)
'Adapted from https://www.rondebruin.nl/win/s1/outlook/bmail4.htm
Dim OutApp As Object
Dim OutMail As Object
Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.CreateItem(0)
With OutMail
.To = ToAddresses
.CC = CcAddresses
.Bcc = BccAddresses
.Subject = Subject
If Body Like "*</*>*" Then
.HtmlBody = Body
Else
.Body = Body
End If
If Not AttachFiles = False Then
If IsArray(AttachFiles) Then
For x = LBound(AttachFiles) To UBound(AttachFiles)
.Attachments.Add (AttachFiles(x))
Next
Else
.Attachments.Add (AttachFiles)
End If
End If
If AutoSend = True Then
.Send
Else
.Display
End If
End With
Set OutMail = Nothing
Set OutApp = Nothing
End Sub
I can't see your screenshot due to a problem with my browser (sorry), but hopefully this should help as at some point in your loop in another sub you can just do something like this;
Call SendEmail (ToAddresses:= "someone#example.com; someoneelse#exmpl.com", _
Subject:="Updated SOH", _
Attachfiles:="c:/Users/Me/Documents/Myfile.txt", _
Autosend:=True)
Some notes on the usage of the sub:
All the arguments are optional
To, CC and Bcc addresses are strings, if you want multiple addresses in any of those fields just separate them with a semicolon, like with any normal email.
Subject and Body are strings too. Body can be HTML or plain t text, it will detect which.
Attachfiles needs to be either a string, or a one-dimensional string array (if attaching multiple files). It should be the full filename including path - see the example I gave above.
If AutoSend is True, the email will send without you ever seeing it (unless there's an error e.g. you didn't enter a valid address to send it to). If it's False (which it defaults to) it will show you the email instead and you can edit it before you hit the send button.
Hope that helps you or anyone reading this!! I find it really useful myself and there's no reason why others shouldn't benefit - as per the first comment in the code I adapted it from an online source anyway.