Invalid identifier in dynamic select - sql

Question

I have a little procedure which should truncate partition if exists
create or replace PROCEDURE drop_partition(p_table_name VARCHAR2, p_load_seq INTEGER)
AS
l_sql_text VARCHAR2(1000 CHAR);
l_part_exists NUMBER;
BEGIN
l_sql_text:= 'SELECT count(*) FROM user_tab_partitions where table_name=' || p_table_name ||' and high_value='||p_load_seq ;
EXECUTE IMMEDIATE l_sql_text INTO l_part_exists;
if (l_part_exists=1) THEN
l_sql_text := 'ALTER TABLE ' || p_table_name || ' DROP PARTITION FOR(' || to_char(p_load_seq) || ')';
EXECUTE IMMEDIATE l_sql_text;
END IF;
END;
If I try to run procedure like this
call drop_partition('test',1);
There is an error:
ORA-00904: "TEST": invalid identifier
ORA-06512: at "DROP_PARTITION", line 8
00904. 00000 - "%s: invalid identifier"
What is the problem and how can I fix it?

Answer 1

You need to enclose the table name in single quotes, which you'll need to escape:
... where table_name=''' || p_table_name ||''' and ...
i.e.:
l_sql_text:= 'SELECT count(*) FROM user_tab_partitions where table_name=''' || p_table_name ||''' and high_value='||p_load_seq ;
There is an alternative quoting mechanism that removes the need to escape the quotes but I think it would be more confusing here.
When using dynamic SQL it can be useful to output the generated statement for debugging purposes, before executing it:
dbms_output.put_line(l_sql_text);
and enabling output in your client before you make the call.
As Justin Cave quite rightly pointed out, the query part of your procedure doesn't need to be dynamic anyway; you can use static SQL:
SELECT count(*)
INTO l_part_exists
FROM user_tab_partitions
where table_name = p_table_name
and high_value = p_load_seq;
Identifiers like table names are uppercase in the data dictionary by default, so you could do upper(p_table_name) in that statement (static or dynamic); but in case you do have any mixed-case quoted identifiers you could instead rely on the caller passing the name in the correct case:
drop_partition('TEST', 1);
... assuming your test table doesn't have a quoted identifier.