Find range by format and then change that format (not using the replace option) - vba

Question

Newbie Jan here with his first question
I am trying to understand the behavior of my vba code. The code is searching for words/sentences with a specific format. When found I would like to adjust these words/sentences by modifying the range that is returned. If I adjust the range as this
that does not produce any problem (loop continues). If I delete the returned range the loop also continues.
Dim myFind As Find
Dim myRange As Range
Set myRange = Application.ActiveDocument.Content
Set myFind = myRange.Find
With myFind
.ClearFormatting
.Font.Underline = wdUnderlineDouble
.Font.Italic = True
End With
Do While myFind.Execute = True
myRange.Font.Bold = True
myRange.Font.StrikeThrough = True
Loop
However If I adjust the format that is used in the search (myRange.font.italic = false) then the loop exit after the first found.
Dim myFind As Find
Dim myRange As Range
Set myRange = Application.ActiveDocument.Content
Set myFind = myRange.Find
With myFind
.ClearFormatting
.Font.Underline = wdUnderlineDouble
.Font.Italic = True
End With
Do While myFind.Execute = True
myRange.Font.Italic = False
Loop
Can someone help me understand why this happens? If I delete the range (myRange.delete) the loop continues (which confuses me). It seems I cannot undo the formatting of what I am searching in this way... but deleting the range gives no problem. I tried to find documentation about this but I am unable to find information about my specific problem.
I have worked around this by selecting the range and then executing the next find and then modifying the selection. This works... but I would still like to understand what is happening.
P.S. This is just a part of the code. The code will be used to create some revisions. That is the reason I do not use the find/replacement options
Thanks!
some extra context
I am dealing with big word files and I want to automatically find 'specially formatted text' and modify this text automatically. Eventually I want the formatted text to become a track change/revision (that is also the reason I do not use the find/replace options). But I would first like to understand what is happening in my code. I understand that the .execute is returning a false and that this is the reason of the exit of the loop. I do not understand why .execute is returning a false while there are still other words/sentences in the document that have the format I was searching for

Answer 1

When using Find in VBA it is best to set .Wrap = wdFindStop to avoid getting into a continuous loop.
If you are not going to use Replace it is also good practice to assign the result of Execute to a variable (although there is a Found property it is considered unreliable).
Performing actions on the found range and then continuing the Find requires the use of Execute again in the loop. It is also necessary to collapse the found range so that Find can continue past it.
When the Find criteria are met the range is redefined to the found range. If you change the properties of that range so that they no longer meet the Find criteria Do While myFind.Execute = True evaluates as False, ending the loop.
The following routine works for all the conditions you mention in your question.
Sub FindFormatting()
Dim findRange As Range
Dim findSucess As Boolean
Set findRange = ActiveDocument.Content
With findRange.Find
.ClearFormatting
.Font.Underline = wdUnderlineDouble
.Font.Italic = True
.Wrap = wdFindStop
findSucess = .Execute
Do While .Found
With findRange.Font
.Italic = False
End With
'collapse range to continue
findRange.Collapse wdCollapseEnd
findSucess = .Execute
Loop
End With
End Sub

Answer 2

This probably should be a comment, but I am too new to add a comment.
I can verify that this happens on my system. To clarify, what you are trying to do is change the formatting for your targets to remove them from the search criteria after you have done your double-strikethrough and bold?
Your code is exiting the loop after the first pass to remove the Italics. That means it has finished the find. I can't explain this.
When I substitute the following for the code changing Italics, I get a message box for each instance found.
`MsgBox "Still in Loop"`
I'm still not clear on why you are not using the Replace function.
================== EDIT - ADDED IN RESPONSE TO COMMENT ==================
Try the following. It is going through the document multiple times but seems to work.
`Sub replacer()
' https://stackoverflow.com/questions/63766819/ms-word-vba-find-object-by-format-and-then-change-that-format-not-using-the-rep
Dim myFind As Find
Dim myRange As Range
Set myRange = Application.ActiveDocument.Content
Set myFind = myRange.Find
With myFind
.ClearFormatting
.Font.Underline = wdUnderlineDouble
.Font.Italic = True
End With
Do While myFind.Execute = True
myRange.Font.Bold = True
myRange.Font.StrikeThrough = True
Loop
'
StartOver:
Set myRange = Application.ActiveDocument.Content
Set myFind = myRange.Find
With myFind
.ClearFormatting
.Font.Underline = wdUnderlineDouble
.Font.Italic = True
.Font.StrikeThrough = True
.Font.Bold = True
End With
Do While myFind.Execute = True
' MsgBox "Still in Loop"
myRange.Font.Italic = False
If myFind.Found = True Then GoTo StartOver
Loop
End Sub`
I still have no explanation for why this is happening.