VBA - What is the purpose of the `With` statement [closed] - vba

Question

Closed. This question is opinion-based. It is not currently accepting answers.
Want to improve this question? Update the question so it can be answered with facts and citations by editing this post.
Closed 2 years ago.
Improve this question
I read the With-Statement documentation from Microsoft and still don't understand what the purpose of the With statement is...
Xpost from Reddit, thought this should really be somewhere on Stack Overflow and couldn't find any questions of this nature.

Answer 1

Introduction to With
Imagine the following code (Example A):
ThisWorkbook.Sheets(1).Range("A1").Font.Color = rgb(255,0,0)
ThisWorkbook.Sheets(1).Range("A1").Font.Bold = true
ThisWorkbook.Sheets(1).Range("A1").Font.Italic = true
ThisWorkbook.Sheets(1).Range("A1").Font.Size = 16
If we count the .s, in this example there are 13. This means that objects are accessed via a property accessor, 13 times in our code.
What happens when we use a With statement instead? (Example B):
With ThisWorkbook.Sheets(1).Range("A1").Font
.Color = rgb(255,0,0)
.Bold = true
.Italic = true
.Size = 16
End With
If we count the .s in the new code, we see property accessors are only called 7 times! So we just halfed the amount of work that VBA had to do by using a With statement!
This is the primary benefit of using the With statement.
How it works internally
Internally VBA is doing something like this (Example C):
Dim temp1 as Object
set temp1 = ThisWorkbook.Sheets(1).Range("A1").Font
temp1.Color = rgb(255,0,0)
temp1.Bold = true
temp1.Italic = true
temp1.Size = 16
set temp1 = nothing 'More specifically temp1 now calls IUnknown::release()
So you can actually imitate the behaviour of With with this code, but With uses "hidden variables" which don't pollute your local variable scope, so this may be preferred.
Performance Caveats
In regards to performance, the With statement can be used in such a way that it has a performance detriment instead of a performance benefit.
1. A is a local variable
Dim A as SomeObject
set A = new SomeObject
With A
.B = 1
.C = 2
.D = 3
End With
In this case A is a local variable. If we run through our conversion:
Dim A as SomeObject
set A = new SomeObject
Dim temp1 as SomeObject 'Unnecessary call
set temp1 = A 'Unnecessary call
temp1.B = 1
temp1.C = 2
temp1.D = 3
set temp1 = nothing
We see there is potentially some performance detriment in our code, because temp1 needs to be defined and set. The performance decrease will be relatively negligible compared to the property accessors though, so it's unlikely to be noticable. Note that the performance decrease is largely negligible because setting an object doesn't transfer the whole object, but transfer a pointer to the object, which is extremely performant.
PS: This performance degradation is just hypothetical at the moment, I'll confirm whether this is true or whether the performance is optimised away by the compiler.
2. A is a MEMBER variable
If we have a class with the following code:
Public A as object
Sub Test
With A
.B = 1
.C = 2
.D = 3
End With
End Sub
In this case A is a member/property variable. So actually some information is hidden. Let's correct that:
Public A as object
Sub Test
With Me.A
.B = 1
.C = 2
.D = 3
End With
End Sub
Ah, now we can see that by using With we are essentially saving 3 member accessor calls:
Dim Temp1 as object
set Temp1 = Me.A
Temp1.B = 1
Temp1.C = 2
Temp1.D = 3
set temp1 = nothing
vs
Me.A.B = 1
Me.A.C = 2
Me.A.D = 3
Ultimately what I'm saying is VBA may be using hidden variables that you can't see and thus what's really going on under the hood is very context specific. What you are doing may warrant the usage of With in some cases and others not. If in doubt, use With because the performance benefits of getting it wrong far outweigh the performance detriments otherwise.
Note: There are a few small benefits to the With statement regarding speed of writing code and representation of hierarchy, however these are mainly my personal opinion and do not belong here.
P-Code and Performance Measurements
In case interested, here are some dumps of the PCode for a set of examples with and without the With Statement
Of course the P-Code is only half the story as different P-Code operations will each have different speeds. Here's a comparison.
The first 3 columns display a test with the 3 cases described at the beginning of this post. The rest of the tests are relatively random but here's what I learnt:
Local Variables in a with statement appear to be much faster than accessing Member variables.
Using with has performance penalties for small number of calls.
As expected With A.O.O performs signficantly better than A.O.O.Prop=...
With actually has noticable speed difference. Therefore if you can try to keep your With statements outside of any loops you have!
Note: all tests ran on Mac version of VBA in Excel 2011
Note: All tests run over 10^8 iterations - this means these performance differences, although there, are tiny!!