Attaching additional lines on top of a Access CSV export - vba

Question

I have a process in MS Access where I am exporting the result of a query into a csv format using the DoCmd TransferText method, and using an export specification to contain the field names.
However, I need to attach to the beginning of this file several lines- all of a fixed value- I'm naming this in my code with vbCrLf to separate the several lines I need. How can I append this to the top of the file after it is created. So my file needs to look like this, with the three extra lines for example at the top, with the csv export contents directly below. How can I achieve this? Thanks!
***(need this line 1)
(need this line 2)
(need this line 3)***
field1,field2,field3
x, y, z

Answer 1

As #TimWilliams has suggested, you will need to use VBA to do this. Below is some code that exports the query to a text file using .TransferText, then opens it and imports the data as one chunk, before writing back out the three header lines and the original data:
Sub sExportCSV()
On Error GoTo E_Handle
Dim strFile As String
Dim strLine1 As String
Dim strLine2 As String
Dim strLine3 As String
Dim strData As String
Dim intFile As Integer
strLine1 = "This is line 1"
strLine2 = "This is the second line"
strLine3 = "And this is the last line"
strFile = "J:\test-data\csv.txt"
DoCmd.TransferText acExportDelim, , "qdfExport", strFile, False
intFile = FreeFile
Open strFile For Input As intFile
strData = Input(LOF(intFile), intFile)
Close #intFile
intFile = FreeFile
Open strFile For Output As intFile
Print #intFile, strLine1 & vbCrLf & strLine2 & vbCrLf & strLine3 & vbCrLf & strData
Close #intFile
sExit:
On Error Resume Next
Close #intFile
Exit Sub
E_Handle:
MsgBox Err.Description & vbCrLf & vbCrLf & "sExportCSV", vbOKOnly + vbCritical, "Error: " & Err.Number
Resume sExit
End Sub
Regards,