Send invites for share folder Items - vba

Question

We use the following code to create a number of items in a shared calendar. Everything works out, only the invites are not send to the optional attendees. Unfortunately the MS Docs are a bit unclear in this area:
Sub DoOne(Calendar, Subject, Start, Duration, Category)
Dim Appointment As Outlook.AppointmentItem
Dim Attendee As Outlook.Recipient
If Subject <> "" Then
Set Appointment = Calendar.Items.Add
With Appointment
.Start = Start
.Duration = Duration
.ReminderSet = False
.Subject = Subject
.Categories = Category
Set Attendee = Appointment.Recipients.Add("distrubutionlist")
Attendee.Type = olOptional
Appointment.Move Calendar
Appointment.Send
End If
End Sub
Also tried this with the property OptionalAttendees.Add but also there no invites are generated.

Answer 1

You must set the meeting status for the appointment first by using the AppointmentItem.MeetingStatus property which sets an OlMeetingStatus constant specifying the meeting status of the appointment.
Sub CreateAppt()
Dim myItem As Object
Dim myRequiredAttendee, myOptionalAttendee, myResourceAttendee As Outlook.Recipient
Set myItem = Application.CreateItem(olAppointmentItem)
myItem.MeetingStatus = olMeeting
myItem.Subject = "Strategy Meeting"
myItem.Location = "Conference Room B"
myItem.Start = #9/24/2020 1:30:00 PM#
myItem.Duration = 90
Set myRequiredAttendee = myItem.Recipients.Add("Eugene Astafiev")
myRequiredAttendee.Type = olRequired
Set myOptionalAttendee = myItem.Recipients.Add("Kevin Kennedy")
myOptionalAttendee.Type = olOptional
Set myResourceAttendee = myItem.Recipients.Add("Conference Room B")
myResourceAttendee.Type = olResource
myItem.Display
End Sub
Also, you need to pay special attention to the Move method which is called right before the Send one. It moves a Microsoft Outlook item to a new folder and returns an Object value that represents the item that has been moved to the designated folder. So, your code shouldn't call the Move method or handle it gracefully:
movedItem = Appointment.Move Calendar
movedItem.Send

Answer 2

With these two changes worked, thanks, Eugene.
The working code reads:
Sub DoOne(Calendar, Subject, Start, Duration, Category)
Dim Appointment As Outlook.AppointmentItem
Dim Attendee As Outlook.Recipient
If Subject <> "" Then
Set Appointment = Calendar.Items.Add
With Appointment
.MeetingStatus = olMeeting
.Start = Start
.Duration = Duration
.ReminderSet = False
.Subject = Subject
.Categories = Category
End With
Set Attendee = Appointment.Recipients.Add("distributionlist")
Attendee.Type = olOptional
Attendee.Resolve
Appointment.Send
End If
End Sub