Make date variable in a oracle query using VBA - sql

Question

first I'm sorry for the poor english but I'll try my best.
I have an oracle query running in a VBA macro and I need to set the date in the sql select as a variable that relates to a sheet cell, I already managed to make the sql consult work.
I would really appreciate some help with this, I'm really stuck, down goes the working code.
Private Sub cmdConexaoBD_Click()
Dim sql As String
Dim cn As ADODB.Connection
Dim rs As ADODB.Recordset
Dim i As Integer
'define a conexão com o banco de dados
Set cn = New ADODB.Connection
cn.CursorLocation = adUseClient
cn.Open "Driver={Microsoft ODBC for Oracle}; " & _
"CONNECTSTRING=database;uid=username;pwd=password;"
Set rs = New ADODB.Recordset
sql = "SELECT NUMOS,MIN(DTINICIOOS),MAX(DTFIMOS),MAX(DTFIMOS)-MIN(DTINICIOOS) FROM PCMOVENDPEND WHERE DATA >= TRUNC(SYSDATE) GROUP BY NUMOS"
rs.Open sql, cn
Range("A1").Value = "OS"
Range("B1").Value = "DT"
Range("C1").Value = "DT"
Range("D1").Value = "TEMPO"
i = 1
If Not rs.EOF Then
Do While Not rs.EOF
Range("A" & i + 1).Value = rs(0)
Range("B" & i + 1).Value = rs(1)
Range("C" & i + 1).Value = rs(2)
Range("D" & i + 1).Value = rs(3)
rs.MoveNext
i = i + 1
Loop
End If
cn.Close
End Sub
Where is written WHERE DATA >= TRUNC(SYSDATE) "DATA" actually is date (it's in portuguese), I want to set the date as a variable referring to a sheet cell, so I can change it in the spreadsheet and import the data of such date without changing the code.
I hope that I made myself clear, Thanks!

Answer 1

For example:
Dim dt
dt = format(Range("F1").Value,"mm/dd/yyyy") 'your date is in F1
sql = " SELECT NUMOS,MIN(DTINICIOOS),MAX(DTFIMOS),MAX(DTFIMOS)-MIN(DTINICIOOS) " & _
" FROM PCMOVENDPEND " & _
" WHERE DATA >= to_date('" & dt & "','mm/dd/yyyy') GROUP BY NUMOS "

Answer 2

It's better to use bind variables, so you need something like this:
Set dbADOCommand = New ADODB.Command
Set dbADOParameter = New ADODB.Parameter
sql = "SELECT NUMOS,MIN(DTINICIOOS),MAX(DTFIMOS),MAX(DTFIMOS)-MIN(DTINICIOOS) FROM PCMOVENDPEND WHERE DATA >= :bindDate GROUP BY NUMOS"
dbADOCommand.CommandText = sql
dbADOCommand.CommandType = adCmdText
dbADOCommand.NamedParameters = true
dbADOCommand.Prepared = true
Set dbADOParameter = dbADOCommand.CreateParameter("bindDate", _
ADODB.DataTypeEnum.adDBDate, _
ADODB.adParamInput, _
8, _
"2020-01-01")
dbADOCommand.Parameters.Append dbADOParameter
Set dbADORecordSet = New ADODB.Recordset
Set dbADORecordSet = dbADOCommand.Execute