TCL/TK Radiobutton with a Dynamic Variable Name in - variables

Question

I am trying to create a TK GUI in TCL that will provide users with the ability to see the current value of a configuration file. This GUI will provide the user the ability to change the config files values to enabled or disabled from radio buttons in the GUI. My configuration file will be a variable length because addition items can be added and I need the GUI to build based on the number of entries in the file. To accomplish this I am trying to loop through the configuration file when creating the GUI and using a variable for each set of radio buttons that can define the user selected value for each Item in the config file.
The configuration file is a simple interface to have the items name associated with a enable (E) or disable (D) value.
Item1 D
Item2 E
Item3 D
Below is the code that I have to generate the radio button for each item in the config with the option to Enable, Disable, or No Change. Here I am trying to create the dynamic variable for each item that will store the selection of the radio button. Besides the current code below I also tried other variations such as -variable selItem${mVal}.
label .optionSelection.c${mVal}_1 -text $mVal
radiobutton .optionSelection.c${mVal}_2 -text "Enable" -variable selItem$mVal \
-value "Enable" -justify left
radiobutton .optionSelection.c${mVal}_3 -text "Disable" -variable selItem$mVal \
-value "Disable" -justify left
radiobutton .optionSelection.c${mVal}_4 -text "No Change" -variable selItem$mVal \
-value "No Change" -justify left
label .optionSelection.c${mVal}_5 -text [dict get $configDict $mVal] \
-textvariable curState${mVal}_5
To get the value of the selItem$mVal (selItemItem1) I have tried to get the value to print with the line below. I have different combination of parenthesis and brackets to create the variable $selItemItem1 so that I can get the value of the selected radio button for that item.
puts "$mVal Variable is $selItem$mVal"
Right now I am just trying to get the variable to print so that I can make it global and reference the value in other procs in the code. I did some research into using either arrays or dictionaries as the variables for the radio buttons. These methods seem like they would be cleaner but I was unable to find examples of how an array or dictionary can be set by the variable.
References Used
tcl: how to use the value of a variable to create a new variable
TCL, How to name a variable that includes another variable
https://www.tutorialspoint.com/tcl-tk/tcl_variables.htm

Answer 1

You definitely want to be using arrays here. To use an array, simply use arrayname($index) as the variable name, and use $arrayname($index) to access the value in the array.
Below is a simple proof of concept on how one might go about writing a configuration screen. I used an = sign in the configuration file to separate the label from the value rather than a space. This code will not work properly if the value contains an = sign.
I also added some descriptive names to display for the user.
This can be expanded on to allow for other types of configuration options, definitely change to present a better user experience, etc.
package require Tk
proc init { } {
global config
global descriptions
set descriptions(Item1) {Item 1 Label}
set descriptions(Item2) {Config B}
set descriptions(Item3) {Item 3}
foreach name [array names descriptions] {
set config($name) D
}
}
proc displayOptions { } {
global config
global descriptions
ttk::frame .optionSel
ttk::label .optionSel.empty -text {}
ttk::label .optionSel.head_on -text On
ttk::label .optionSel.head_off -text Off
grid .optionSel
grid .optionSel.empty .optionSel.head_on .optionSel.head_off
set fh [open t.txt r]
while { [gets $fh line] >= 0 } {
lassign [split $line =] name value
set config($name) $value
}
close $fh
foreach name [array names descriptions] {
ttk::label .optionSel.lab${name} -text $descriptions($name)
ttk::radiobutton .optionSel.c${name}_on -value E -variable config($name)
ttk::radiobutton .optionSel.c${name}_off -value D -variable config($name)
grid .optionSel.lab${name} .optionSel.c${name}_on .optionSel.c${name}_off \
-sticky w
}
ttk::button .optionSel.save -text { Save } -command ::saveOptions
grid .optionSel.save
}
proc saveOptions { } {
global descriptions
global config
set fh [open t.txt w]
foreach name [array names descriptions] {
puts $fh "$name=$config($name)"
}
close $fh
}
init
displayOptions