VBA PPT error while reading CR/LF character - vba

Question

I have encountered an odd problem while writing VBA macro for Ppt document.
In the code I would like to extract text in frames at the very top of each slide of my presentation.
The text is divided by newline character, so first I would like to search for newline character.
I am using Instr function to search for the position of a newline in a string.
The code is the following:
Sub SetTitle()
Dim sl As Slide
Dim sh As Shape
Dim trng As TextRange
Dim asptext() As Variant
For Each sl In ActivePresentation.Slides
For Each sh In sl.Shapes
If sh.Top = 5.403701 Then
Set trng = sh.TextFrame.TextRange
txt = trng.Text
Debug.Print txt
pos = InStr(1, Chr(13), txt)
Debug.Print pos
Debug.Print Asc(Mid(txt, 7, 1))
If pos <> 0 Then
Debug.Print pos
End If
End If
Next sh
Next sl
End Sub
In Immediate window I am getting the following results : https://i.stack.imgur.com/Ig41i.png
The debugger gives an error:
Runtime error '5': Invalid procedure call or argument
for the line
Debug.Print Asc(Mid(txt, 7, 1))
So I suppose that there is a problem in recognizing this NL character.
Do you have any idea why it is like this?

Answer 1

The error comes likely not from any NewLine character but from a string that is too short. Mid(txt, 7, 1) will return an empty string, and that is not a valid parameter for the Asc-function.
To check for Newline-characters, you can use the constants vbCr (same as Chr(13)) and vbLf (same as Chr(10)) and vbCrLf.
If you are unsure about the content of a string, you can use the following function:
Function DumpString(s As String) As String
Const Separator = ", "
' Write all chars of String as ASCII-Value
Dim i As Long
For i = 1 To Len(s)
Dim a As Long, c As String
a = AscW(Mid(s, i, 1))
If a = AscW(vbCr) Then
c = "<CR>"
ElseIf a = AscW(vbLf) Then
c = "<LF>"
ElseIf a = AscW(vbTab) Then
c = "<TAB>"
ElseIf a = 0 Then
c = "<NUL>"
Else
c = Mid(s, i, 1)
End If
DumpString = DumpString & IIf(DumpString = "", "", Separator) & a & "(" & c & ")"
Next i
End Function