Using grep / sed replace values from list with semi colons, new lines as seperators - awk

Question

I am fairly new grep, sed, and awk. I have used them in them past to extract lines and/or replace things from exact lists.
In this case I am confused on how to go about it. I have a two csv files.
My first csv file is names that are separted by spaces and semi colons.
Name,
Frank ,
Frank; John; Rob; ,
John; Nick; ,
The second csv is with location and names
Location, Name,
France, Frank,
John, New Jersey,
Nick, Germany,
Rob, Japan,
I would like the output to add the location as a column next to the name.
Name, Location,
Frank , France,
Frank; John; Rob; , France; New Jersey; Japan,
John; Nick; , New Jersey; Germany,
How can I search through the 2nd csv file by line and treat each name as unique to extract its respective location? Then output it so it keeps the information per line with semi colons..
What I have done do far is:
cat file1.csv | cut -f1 | tr ';' '\t' > file-test.tsv
Thank you.

Answer 1

Your files are formatted somewhat strangely. Comma delimited overall, and individual fields delimited with semicolons, but sometimes with a trailing semicolon and sometimes not.
Also, at the time this answer is written, your second file still has "Location, Name" for the first data row, and "Name, Location" for all the rest. I'm assuming that the actual file is "Location, Name" on every row.
Here's how I'm approaching it:
Make one pass through the 2nd file and create a mapping from name to location
Make one pass through the 1st file and apply the mapping
Here is my solution, using just awk:
# use delimiter of zero or more spaces on either side of a comma
awk -F ' *, *' '
# First line of first file processed; set flag variable
FNR == 1 && NR == 1 {mapfile = 1;}
# Lines 2+ in the map file: save the mapping
mapfile && FNR > 1 {map[$2] = $1;}
# First line of second file; print header and reset flag
FNR == 1 && NR > 1 {print "Name, Location,"; mapfile = 0;}
# Process lines 2+ in the name file (i.e. not the map file)
!mapfile && FNR > 1 {
data = $0;
sub(/ *, *$/,"",data); # remove trailing comma
sub(/ *; *$/,"",data); # remove trailing semicolon
# create "names" array of length "num"
num = split(data,names,/ *; */);
locs = ""; # init location string to empty
for (i = 1; i <= num; i++)
{
locs = locs map[names[i]] "; ";
}
sub(/; $/,",",locs); # change last semicolon to comma
# print original line from name file, and append locations
print $0 " " locs;
}' file2.csv file1.csv
Some more explanation:
NR = "Number of Row" being processed. This starts at 1 and increments forever, regardless of how many files are processed by awk
FNR = "File Number of Row". This starts over at 1 with every file being processed
So when both are 1, the first line of the map file is being processed.
When FNR is 1 but NR is greater than 1, the 2nd file is being processed.
Also,
awk can use regular expressions as delimiters, so I've told it to use a comma with zero or more spaces on either side as the delimiter ( *, *).
$0 = entire line
$1, $2, etc are the individual fields of each line when split using the specified delimiter.
The rest of the logic should be self-evident from the code and comments within the script.
When processing your files in this order
file2.csv = your second file, but with "location, name" order on all rows
file1.csv = your first file
the output is:
Name, Location,
Frank , France,
Frank; John; Rob; , France; New Jersey; Japan,
John; Nick; , New Jersey; Germany,

Answer 2

Assuming the lines of your 2nd file are actually always in location, name order instead of sometimes one, sometimes the other as in the example in your question here's how to output the data you want:
$ cat tst.awk
BEGIN { FS=" *, *"; OFS=" , " }
NR == FNR {
name2loc[$2] = $1
next
}
{
for (i=1; i<=NF; i++) {
n = split($i,names,/ *; */)
for (j=1; j<=n; j++) {
locs = (j>1 ? locs "; " : "") name2loc[names[j]]
}
}
print $1, locs
}
.
$ awk -f tst.awk file2 file1
Name , Location
Frank , France
Frank; John; Rob; , France; New Jersey; Japan;
John; Nick; , New Jersey; Germany;
Massage the output format to suit whatever you really want your output to look like.