Trying to warn if sending from a personal email account - vba

Question

I'm trying to prompt if sending from a personal account in Outlook.
I have the following which works 90% of the time, however sometimes it errors with the following:
You cannot send an item that is already in the process of being sent
Code for reference:
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
Dim Send_Address As String
Dim Prompt As String
' Check Send_From name
Send_Address = Item.SendUsingAccount
Select Case Send_Address
Case "example#domain.uk"
Case Else
Prompt = "You are currently sending this email from " & Send_Address & "" & vbNewLine & "Do you want to proceed?"
If MsgBox(Prompt, vbYesNo + vbQuestion + vbMsgBoxSetForeground, "Check Address") = vbNo Then
Cancel = True
End If
End Select
End Sub

Answer 1

You can't cast an instance of the Account class to a string:
Dim Send_Address As String
Dim Prompt As String
' Check Send_From name
Send_Address = Item.SendUsingAccount
The SendUsingAccount property returns or sets an Account object that represents the account under which the MailItem is to be sent. The SendUsingAccount property can be used to specify the account that should be used to send the MailItem when the Send method is called. This property returns Null (Nothing in Visual Basic) if the account specified for the MailItem no longer exists. For example, here is a sample use case:
Sub SendUsingAccount()
Dim oAccount As Outlook.account
For Each oAccount In Application.Session.Accounts
If oAccount.AccountType = olPop3 Then
Dim oMail As Outlook.MailItem
Set oMail = Application.CreateItem(olMailItem)
oMail.Subject = "Sent using POP3 Account"
oMail.Recipients.Add ("someone#example.com")
oMail.Recipients.ResolveAll
Set oMail.SendUsingAccount = oAccount
oMail.Send
End If
Next
End Sub
So, to check the SMTP address you need to use the following code:
Private Sub Application_ItemSend(ByVal Item As Object, Cancel As Boolean)
Dim account as Outlook.Account
Dim Send_Address As String
Dim Prompt As String
' Check Send_From name
Set account = Item.SendUsingAccount
If Not account Is Nothing then
Send_Address = account.SmtpAddress
Select Case Send_Address
Case "example#domain.uk"
Case Else
Prompt = "You are currently sending this email from " & Send_Address & "" & vbNewLine & "Do you want to proceed?"
If MsgBox(Prompt, vbYesNo + vbQuestion + vbMsgBoxSetForeground, "Check Address") = vbNo Then
Cancel = True
End If
End Select
End If
End Sub