Awk start and end having same string - awk

Question

I would like to print
contents between start and end
contents between start and second occurrence of end
Unfortunately both start and end are having exactly the same value and also end is showing up twice in txt file
Sample file -
My
Dog
Start
has
a nice
tail
end
My
Dog
name
end
is
jay
awk '/Dog/, /Dog/ {print $0}' awktest.txt -> For grabbing contents between two Dog words
awk '/Start/, /end/ {print $0}' awktest.txt -> For grabbing contents between Start and second end

Answer 1

Could you please try following. Written based on shown samples.
awk '
/^start$/{
found=1
}
found;
/^end$/ && ++count==2{
found=""
}
' Input_file
Brief explanation: looking for line which has start in it then setting found to 1, then checking condition if found is set then print the line. Also checking condition if a line starts with end word and it's count is 2 then set found to NULL, so that we can stop printing from there.
Above will print lines with start and end too, in case you want to skip these lines then try following.
awk '
/^start$/{
found=1
next
}
/^end$/ && ++count==2{
found=""
}
found;
' Input_file

Answer 2

You can do both of these with a simple state machine with an echo variable e. The first (on one line):
pax> awk '/end/ {e = 0} e == 1 {print} /Start/ {e = 1}' inputFile
has
a nice
tail
Echo starts off then, for each line (order is important here):
an end line will turn echo off;
a line will print if echo is on;
a Start line will turn it on.
The second is similar but echo becomes a counter rather than a flag. That way, it only turns off on the second end:
pax> awk '/end/ {e -= 1} e > 0 {print} /Start/ {e = 2}'
has
a nice
tail
end
My
Dog
name
And, in fact, you can combine them if you're happy to supply the count (use 1, 2 or any other value you may need):
pax> awk -vc=2 '/end/ {e -= 1 } e > 0 {print} /Start/ {e = c}'
has
a nice
tail
end
My
Dog
name
You may need to watch out for edge cases such as what to do when Start appears within the section you're echoing. But that's just a matter of tweaking the state machine to detect that and act accordingly. At the moment, it will restart the counter. If you want it to not do that, use:
e == 0 && /Start/ {e = c}
for the final clause.

Answer 3

$ awk -v start=start -v end=end '$0~end && e++{exit} s; $0~start{s=1}' file
$ awk -v start=dog -v end=dog '...' file
will print between start and second occurence of end