How to create a techniqueIcon from RGB bitmap in GMS 3.x - dm-script

Question

In GMS 3.x we can create "Techniques" with customized techniqueIcon:
Image techniqueIcon := RGBImage( "Test icon", 4, 75, 75 )
techniqueIcon = RGB( icol, irow, iradius )
String techniqueName = "MyTechnique"
Object technique = CreateTechnique( techniqueName, techniqueIcon )
How do I make the "techniqueIcon" to have proper transparency (i.e. alpha channel)? I tried the RGBA() function but the result icon still does not have the transparency as I desired. I can, however, create the icon in *.PNG format from an external application and assign it to a technique via the "Manage Custom Techniques ..." menu command.

Answer 1

I believe there is currently no proper way to set transparency to icons via scripting. DM scripting does not fully support alpha-values in RGB images.
However, your comment was interesting and send me experimenting.
The tag saved at the provided location, when watched in the tag-browser, does not seem to be a typical "array" tag, because those would display as (values not shown). Instead, it shows as a long string.
The size of the tag (as given by TagGroupGetTagSize()) in bytes matches 4 bytes * width * height of the bitmap.
Assuming that each pixel in the icon has a byte-sizes values for R , G , B and Alpha, I'm guessing the "string" is just DigitalMicrograph's way of (mis)representing the binary array data, because it's not a known array form (aka image).
This led me to come up with the following script:
RGBImage GetBitMapFromCustomTechniqueIcon( number index)
{
RGBImage bitmap
taggroup tg
string path = "WorkflowManager:Custom Techniques:["+index+"]"
if ( !GetPersistentTagGroup().TagGroupGetTagAsTagGroup(path,tg) ) Throw("Tagpath not found")
number w,h
if ( !tg.TagGroupGetTagAsLong("Bitmap height",h) ) Throw("Height tag not found")
if ( !tg.TagGroupGetTagAsLong("Bitmap width",w) ) Throw("Width tag not found")
string str
if ( !tg.TagGroupGetTagAsString("Bitmap data",str) ) Throw("Bitmap data tag not found.")
{
number nPts = w*h
if ( str.len()/4 != nPts ) Throw("Data length does not seem to match icon size")
image imgR := IntegerImage("Red",1,0,w,h)
image imgG := IntegerImage("Green",1,0,w,h)
image imgB := IntegerImage("Blue",1,0,w,h)
image imgA := IntegerImage("Alpha",1,0,w,h)
// Browse and convert string
for( number i=0; i<nPts; i++)
{
imgR[i%w,i/w] = asc(str.mid(i*4,1))
imgG[i%w,i/w] = asc(str.mid(i*4+1,1))
imgB[i%w,i/w] = asc(str.mid(i*4+2,1))
imgA[i%w,i/w] = asc(str.mid(i*4+3,1))
}
imgR.FlipVertical()
imgG.FlipVertical()
imgB.FlipVertical()
imgA.FlipVertical()
bitmap := RGBA(imgR,imgG,imgB,imgA)
}
return bitmap
}
With this script, I'm indeed able to read out the stored icon and show it as RGB image.
However, I was less successful when writing the tags. The icons never update correctly, even after a DM restart.
void WriteCustomTechniqueIcon(number index,image imgR,image imgG,image imgB,image imgA)
{
taggroup tg
string path = "WorkflowManager:Custom Techniques:["+index+"]"
if ( !GetPersistentTagGroup().TagGroupGetTagAsTagGroup(path,tg) ) Throw("Tagpath not found")
number w = imgR.ImageGetDimensionSize(0)
number h = imgR.ImageGetDimensionSize(1)
if ( w != imgG.ImageGetDimensionSize(0) ) Throw( "Images not of same size" )
if ( h != imgG.ImageGetDimensionSize(1) ) Throw( "Images not of same size" )
if ( w != imgB.ImageGetDimensionSize(0) ) Throw( "Images not of same size" )
if ( h != imgB.ImageGetDimensionSize(1) ) Throw( "Images not of same size" )
if ( w != imgA.ImageGetDimensionSize(0) ) Throw( "Images not of same size" )
if ( h != imgA.ImageGetDimensionSize(1) ) Throw( "Images not of same size" )
tg.TagGroupSetTagAsLong("Bitmap height",h)
tg.TagGroupSetTagAsLong("Bitmap width",w)
imgR.FlipVertical()
imgG.FlipVertical()
imgB.FlipVertical()
imgA.FlipVertical()
// Create encoded data string
string str = ""
number nPts=w*h
for( number i=0; i<nPts; i++)
{
str+= uncchr(sum(imgR[i%w,i/w]))
str+= uncchr(sum(imgG[i%w,i/w]))
str+= uncchr(sum(imgB[i%w,i/w]))
str+= uncchr(sum(imgA[i%w,i/w]))
}
tg.TagGroupSetTagAsString("Bitmap data",str)
}
Not sure what I'm missing out on here.
EDIT
I'm getting nearly there when I trick the system and write a proper uint8 array of 4 times the image size using the code below:
void WriteCustomTechniqueIcon2(number index,image imgR,image imgG,image imgB,image imgA)
{
taggroup tg
string path = "WorkflowManager:Custom Techniques:["+index+"]"
if ( !GetPersistentTagGroup().TagGroupGetTagAsTagGroup(path,tg) ) Throw("Tagpath not found")
number w = imgR.ImageGetDimensionSize(0)
number h = imgR.ImageGetDimensionSize(1)
if ( w != imgG.ImageGetDimensionSize(0) ) Throw( "Images not of same size" )
if ( h != imgG.ImageGetDimensionSize(1) ) Throw( "Images not of same size" )
if ( w != imgB.ImageGetDimensionSize(0) ) Throw( "Images not of same size" )
if ( h != imgB.ImageGetDimensionSize(1) ) Throw( "Images not of same size" )
if ( w != imgA.ImageGetDimensionSize(0) ) Throw( "Images not of same size" )
if ( h != imgA.ImageGetDimensionSize(1) ) Throw( "Images not of same size" )
tg.TagGroupSetTagAsLong("Bitmap height",h)
tg.TagGroupSetTagAsLong("Bitmap width",w)
imgR.FlipVertical()
imgG.FlipVertical()
imgB.FlipVertical()
imgA.FlipVertical()
image array := IntegerImage("",1,0,w*4,h)
array.slice2(0,0,0, 0,w,4,1,h,1) = imgB
array.slice2(1,0,0, 0,w,4,1,h,1) = imgG
array.slice2(2,0,0, 0,w,4,1,h,1) = imgR
array.slice2(3,0,0, 0,w,4,1,h,1) = imgA
tg.TagGroupSetTagAsArray("Bitmap data",array)
}
The icon loads after DM is restarted.
However, the colors are all dimmed down and I don't really know why. Alpha, however, is working (including mixing values)