Sort not working using dbOpenDynaset in vba - vba

Question

How can I sort the name of the wine in asc order using dbOpenDynaset
Here is my vba code
Dim critère As String
Dim strFormateDesNomVins As String
Dim maBase As Database
Dim tblVins As Recordset
Set maBase = CurrentDb()
Set tblVins = maBase.OpenRecordset("tblVins", dbOpenDynaset)
critère = "[NoTypeVin]=" & typeVin
tblVins.Sort = "NomVin ASC"
tblVins.FindFirst critère
Do Until tblVins.NoMatch
strFormateDesNomVins = strFormateDesNomVins & tblVins!NomVin & vbCrLf
tblVins.FindNext critère
Loop
This part of the code does not work
tblVins.Sort = "NomVin ASC"
I want to sort the name of wine in asc order How can I do this using dbOpenDynaset Thank you for your help.

Answer 1

It works, but you must assign the sorted recordset to a (new) recordset and then use that:
tblVins.Sort = "NomVin ASC"
Set tblVins = tblVins.OpenRecordset()
or:
Set tblVinsSorted = tblVins.OpenRecordset()
or create it sorted initially:
Set tblVins = maBase.OpenRecordset("Select * From tblVins Order By NomVin", dbOpenDynaset)

Answer 2

Rather than trying to use .Sort and .FindFirst/.FindNext, it is better to open a recordset that is already filtered and ordered as you want:
Sub sWine()
Dim db As DAO.Database
Dim rsData As DAO.Recordset
Dim strSQL As String
Dim strFormateDesNomVins As String
Dim typeVin As Long
typeVin = 1
Set db = DBEngine(0)(0)
strSQL = "SELECT NomVin FROM tblVins WHERE NoTypeVin=" & typeVin & " ORDER BY NomVin ASC;"
Set rsData = db.OpenRecordset(strSQL, dbOpenDynaset)
If Not (rsData.BOF And rsData.EOF) Then
Do
strFormateDesNomVins = strFormateDesNomVins & rsData!NomVin & vbCrLf
rsData.MoveNext
Loop Until rsData.EOF
End If
Debug.Print strFormateDesNomVins
rsData.Close
Set rsData = Nothing
Set db = Nothing
End Sub
In the example above, I am creating a recordset that is based on tblVins, sorted by NomVin, and only having records where NoTypeVin is equal to typeVin (in this case 1).
Regards