Checkboxes are keeping myCurrencyManager.AddNew() from working properly - vb.net

Question

I have a fully functional Windows forms app developed with a read-only datagridview bound to an Access DB.
Databound textboxes are used to edit fields. I then added 3 Checkbox fields to the DB, datagridview and the form. Then added chkName.DataBindings.Add("Checked", DBTable,"Field") just like the Textboxes. The checkboxes work properly displaying the correct data.
Only now when I try to add a row using myCurrencyManager.AddNew() it doesn't work. It does nothing except add a non-accessible row to the end of the datagridview. When I comment out the Checkbox DataBindings lines, everything works properly (without functioning checkboxes).
Any ideas what is wrong?
Here is the code:
Public Class frmRoutes
Dim RoutesConnection As OleDbConnection
Dim JS1Adapter As New OleDbDataAdapter
Dim JS1Table As New DataTable("JOBSITES")
Dim JSBS As BindingSource
Dim JS1State As String = "Edit"
Private Sub frmRoutes_Load(sender As Object, e As EventArgs) Handles MyBase.Load
RoutesConnection = New OleDbConnection("Provider=Microsoft.ACE.OLEDB.12.0; Data Source = C:\Microsoft\JS1TestDB.mdb")
RoutesConnection.Open()
Dim JobSitesCommand = New OleDbCommand _
("SELECT REF, STREET, CITY, SPEC, HELPER " +
"FROM Jobsites ORDER BY REF", RoutesConnection)
JS1Adapter.SelectCommand = JobSitesCommand
JS1Adapter.Fill(JS1Table)
JSBS = New BindingSource()
JSBS.DataSource = JS1Table
grdJobSites.DataSource = JSBS
txtRef.DataBindings.Add("Text", JSBS, "REF")
txtStreet.DataBindings.Add("Text", JSBS, "STREET")
txtCity.DataBindings.Add("Text", JSBS, "CITY")
'chkSpecial.DataBindings.Add("Checked", JSBS, "SPEC") 'THESE 2 CHECKBOX DATABINDINGS CAUSE THE 'ADDNEW' METHOD TO FAIL
'chkHelper.DataBindings.Add("Checked", JSBS, "HELPER")
End Sub
Private Sub btnAdd_Click(sender As Object, e As EventArgs) Handles btnAdd.Click
Try
JSBS.AddNew()
Catch ex As Exception
MessageBox.Show("Error Adding a New row.", "Error", MessageBoxButtons.OK, MessageBoxIcon.Error)
End Try
JS1State = "Add"
End Sub
Private Sub btnCancel_Click(sender As Object, e As EventArgs) Handles btnCancel.Click
JSBS.CancelEdit()
JS1State = "View"
End Sub
End Class

Answer 1

The issue is exactly as I already said: nullable data. I just tested this code (an actual minimal example):
Public Class Form1
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim table As New DataTable
With table.Columns
.Add("Name", GetType(String))
.Add("Flag", GetType(Boolean))
End With
With table.Rows
.Add("Peter", True)
.Add("Paul", False)
.Add("Mary", True)
End With
BindingSource1.DataSource = table
TextBox1.DataBindings.Add("Text", BindingSource1, "Name")
CheckBox1.DataBindings.Add("Checked", BindingSource1, "Flag")
End Sub
End Class
and an invalid cast exception occurred when adding a new row (via a BindingNavigator) because the Flag column contained DBNull.Value by default and that cannot be cast as type Boolean, which is required for the Checked property. There are two potential solutions. The best one depends on whether you might want to be able save null values or not.
If you don't want to save null values then specify a default Boolean value for that column. That would probably be False but may be True if you want it. That way, when a new row is added, that column already contains a Boolean value that is compatible with the Checked property. In my example, this:
.Add("Flag", GetType(Boolean))
becomes this:
.Add("Flag", GetType(Boolean)).DefaultValue = False
In your case, you'd have to get the appropriate column from the DataTable after populating it and set that property.
Set the ThreeState property of the CheckBox to True, bind to the CheckState property instead of the Checked property and do your own translation between nullable Boolean data in the data source and CheckState values in the control. Making that change to my example might look like this:
Public Class Form1
Private WithEvents checkStateBinding As Binding
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
Dim table As New DataTable
With table.Columns
.Add("Name", GetType(String))
.Add("Flag", GetType(Boolean))
End With
With table.Rows
.Add("Peter", True)
.Add("Paul", False)
.Add("Mary", True)
End With
BindingSource1.DataSource = table
TextBox1.DataBindings.Add("Text", BindingSource1, "Name")
checkStateBinding = New Binding("CheckState", BindingSource1, "Flag")
CheckBox1.DataBindings.Add(checkStateBinding)
End Sub
Private Sub CheckStateBinding_Format(sender As Object, e As ConvertEventArgs) Handles checkStateBinding.Format
'Convert from nullable Boolean to CheckState.
If TryCast(e.Value, DBNull) Is DBNull.Value Then
e.Value = CheckState.Indeterminate
ElseIf CBool(e.Value) Then
e.Value = CheckState.Checked
Else
e.Value = CheckState.Unchecked
End If
End Sub
Private Sub CheckStateBinding_Parse(sender As Object, e As ConvertEventArgs) Handles checkStateBinding.Parse
'Convert from CheckState to nullable Boolean.
Select Case DirectCast(e.Value, CheckState)
Case CheckState.Indeterminate
e.Value = DBNull.Value
Case CheckState.Checked
e.Value = True
Case CheckState.Unchecked
e.Value = False
End Select
End Sub
End Class
The Binding raises its Format event when it needs to get data from the data source for the control and its Parse event when it needs to get data from the control for the data source. If types and/or values don't match up between the two, you can do your own translation.