How to pass arraylist to stored procedure in VB - vb.net

Question

How to pass an ArrayList to the stored procedure in this code below
Dim sqlcon As SqlConnection = New SqlConnection(ConfigurationManager.ConnectionStrings("connect").ConnectionString)
Dim sda As New SqlDataAdapter
Dim cmd As New SqlCommand
Dim dt As New DataTable
Dim arr As New ArrayList
arr.Add("#type,1") '--------------How do I pass this to my stored procedure
cmd = New SqlCommand("usp_demo", sqlcon)
cmd.CommandType = CommandType.StoredProcedure
sda.SelectCommand = cmd
sda.Fill(dt)
Below is the Stored Procedure used - "usp_demo"
alter procedure usp_demo
#type int
As
Begin
If #type = 1
Begin
select * from sample
End
If #type = 2
Begin
select * from nextnode
End
End

Answer 1

The design of this code depends on how many parameters you need to pass. We don't want the user interface code worrying about the database so we don't want to create SqlParameters in the UI. Let's say you have 5 parameters of different types. Just pass the values to the Function. If there are many parameters, create a class for the entity. Pass an instance of the class with the properties set in the UI code. You could even pass a List(Of YourClass) and loop through it resetting the .Value property of the Parameters.
Simple method as per your question.
Private Function GetData(type As Integer) As DataTable
Dim dt As New DataTable
Using sqlcon As New SqlConnection(),
cmd As New SqlCommand("usp_demo", sqlcon)
cmd.Parameters.Add("#type", SqlDbType.Int).Value = type
cmd.CommandType = CommandType.StoredProcedure
sqlcon.Open()
dt.Load(cmd.ExecuteReader)
End Using
Return dt
End Function
Usage
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
Dim dt = GetData(1)
DataGridView1.DataSource = dt
End Sub
More than on parameter
Private Function InsertRecord(FName As String, LName As String) As Integer
Dim i As Integer
Using cn As New SqlConnection(ConfigurationManager.ConnectionStrings("connect").ConnectionString),
cmd As New SqlCommand("Insert Into Employee (FirstName, LastName) Values (#First, #Last);", cn)
cmd.Parameters.Add("#First", SqlDbType.NVarChar, 100).Value = FName
cmd.Parameters.Add("#Last", SqlDbType.NVarChar, 100).Value = LName
cn.Open()
i = cmd.ExecuteNonQuery
End Using
Return i
End Function
usage
Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
Dim i = InsertRecord("John", "Smith")
If i = 1 Then
MessageBox.Show("Success")
Else
MessageBox.Show("Error")
End If
End Sub
Create a class
Public Class Employee
Public Property FirstName As String
Public Property MiddleName As String
Public Property LastName As String
Public Property DOB As Date
Public Property Weight As Integer
Public Property Department As String
Public Property IsHourly As Boolean
Public Property Rate As Decimal
Public Sub New(FName As String, MName As String, LName As String, Birth As Date, lbs As Integer, Dep As String, Hourly As Boolean, Pay As Decimal)
FirstName = FName
MiddleName = MName
LastName = LName
DOB = Birth
Weight = lbs
Department = Dep
IsHourly = Hourly
Rate = Pay
End Sub
End Class
This class could probably be used other ways in your application.
Private Function InsertCompleteEmployee(e As Employee) As Integer
Dim i As Integer
Dim sql = "Insert Into EmployeeComplete (FirstName, MiddleName, LastName, DOB, Weight, Department, IsHourly, Rate) Values (#FName, #MName, #LName, #Birth, #lbs, #Dep, #Hourly, #Rate);"
Using cn As New SqlConnection(ConfigurationManager.ConnectionStrings("connect").ConnectionString),
cmd As New SqlCommand(sql, cn)
With cmd.Parameters
.Add("#FName", SqlDbType.NVarChar, 100).Value = e.FirstName
.Add("#MName", SqlDbType.NVarChar, 100).Value = e.MiddleName
.Add("#LName", SqlDbType.NVarChar, 100).Value = e.LastName
.Add("#Birth", SqlDbType.Date).Value = e.DOB
.Add("#lbs", SqlDbType.Int).Value = e.Weight
.Add("#Dep", SqlDbType.NVarChar, 100).Value = e.Department
.Add("#Hourly", SqlDbType.Bit).Value = e.IsHourly
.Add("#Rate", SqlDbType.Decimal).Value = e.Rate
End With
cn.Open()
i = cmd.ExecuteNonQuery
End Using
Return i
End Function
Usage
Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
Dim Emp As New Employee(TextBox1.Text, TextBox2.Text, TextBox3.Text, DateTimePicker1.Value, 200, "Accountin", CheckBox1.Checked, 8.5D)
Dim i = InsertCompleteEmployee(Emp)
If i = 1 Then
MessageBox.Show("Success")
Else
MessageBox.Show("Error")
End If
End Sub
The Using...End Using blocks ensure that your database objects are closed and disposed. In these Functions both the connection and the command are part of the block. Note the comma at the end of the Using line.
Always use parameters to avoid sql injection and make the sql string easier to write.

Answer 2

Personally i generally use a key value pair [KeyValuePair(Of String, List(Of SqlParameter))]; I hope that's what you were looking for; probably someone will have a better solution
Public Function ExecuteSelectionSP(ByVal MyConnectionString As String, ByVal KVP As KeyValuePair(Of String, List(Of SqlParameter)), ByRef MyTable As DataTable) As Boolean
Dim Result As Boolean
Dim sqlcon As New SqlConnection(MyConnectionString)
Dim reader As SqlDataReader
Dim cmd As New SqlCommand
cmd.CommandType = CommandType.StoredProcedure
cmd.CommandText = KVP.Key
For Each MyParameter As SqlParameter In KVP.Value
cmd.Parameters.Add(MyParameter)
Next
cmd.Connection = sqlcon
Try
If sqlcon.State = ConnectionState.Closed Then sqlcon.Open()
reader = cmd.ExecuteReader()
MyTable.Load(reader)
If sqlcon.State = ConnectionState.Open Then sqlcon.Close()
Result = True
Catch ex As Exception
MsgBox("Execution error :" & vbCrLf & KVP.Key & vbCrLf & vbCrLf & ex.Message, MsgBoxStyle.Critical, "Errore")
Result = False
End Try
Return Result
End Function