VBA conditions for a UserForm - vba

Question

I am new on VBA. I want to put some restrictions on my inputs in the UserForm. I want My variable to be a number (the user should select the row Number) and if she/he put text or leave it blank an error message should appear. This is the code I have:
Public Sub AddPolicy_Click()
Dim RowNumber As Integer
RowNumber = TextBox1.Value
If RowNumber = "" Then
MsgBox "Error Row Number- enter a value!", vbOKCancel + vbCritical, "Error"
ElseIf VarType(RowNumber) = vbString Then
MsgBox "Error Row Number- enter a Numerical Value!", vbOKCancel + vbCritical, "Error"
End If
Range("A1") = RowNumber
End Sub
I know that the problem is because I declare my variable RowNumber as an Integer, But if I do not do that the software does not recognize my variable, and show me the error message for text, blank and number. SO I do not know how can I solve this.
Thank you in advance for your help

Answer 1

How about this?
Public Sub AddPolicy_Click()
Dim RowNumber As String
RowNumber = TextBox1.Value
If RowNumber = "" Then
MsgBox "Error Row Number- enter a value!", vbOKCancel + vbCritical, "Error"
ElseIf Not IsNumeric(RowNumber) Then
MsgBox "Error Row Number- enter a Numerical Value!", vbOKCancel + vbCritical, "Error"
End If
Range("A1") = RowNumber
End Sub
Edit: About the declaration of String, integer etc.: I know people tend to be very particular about this. But it really doesnt make a difference efficiency-wise for most macros. Here for example you wont gain anything by declaring it better. Even simply not dim'ing it would work nicely.

Answer 2

You could try this code.
The change event on the textbox will stop you being able to enter anything except numerics.
Private LastText As String '<-- place this at the very top of the module.
Private Sub TextBox1_Change()
With Me.TextBox1
'Allow only whole numbers.
If .Text Like "[!0-9]" Or Val(.Text) < -1 Or .Text Like "?*[!0-9]*" Then
.Text = LastText
Else
LastText = .Text
End If
End With
End Sub
Private Sub TextBox1_AfterUpdate()
'Remove any leading or trailing spaces
'(although the Change event should stop you entering spaces).
Me.TextBox1 = Trim(Me.TextBox1)
End Sub
Private Sub AddPolicy_Click()
With Me.TextBox1
If .Value <> "" Then
'Fully qualify where you want to put the data, or it will
'put it in A1 of whichever sheet happens to be active.
ThisWorkbook.Worksheets("Sheet1").Range("A1") = Me.TextBox1
Else
MsgBox "Invalid or no value entered.", vbCritical + vbOKOnly
End If
End With
End Sub