How can get a list of included records in a Word Mail Merge Document? - vba

Question

I have a Mail Merge Document which is controlled via VBA. After the user selects the records he wants to print, I want these to get a print date set in the database. For that I need a list of the records included in the mail merge.
I tried using the .Included property, setting ThisDocument.MailMerge.DataSource.ActiveRecord = wdFirstRecord (I later removed the wdFirstRecord in favour of 1 since it was giving me trouble)
and then checking for ThisDocument.MailMerge.DataSource.Included to be true but got a 5852 runtime-error "Object not available". EDIT: I used the following code to iterate over the records. When I remove either of the commented .Included statements, I get said error. (The execution does not feel as slow as yesterday anymore, though it is not especially fast.)
Function outputRecords(Optional limitRecords = -1)
With ThisDocument.MailMerge.DataSource
Dim str
For currentFieldNameIndex = 1 To .FieldNames.Count
str = str & .FieldNames(currentFieldNameIndex) & vbTab
Next
Debug.Print str
For currentRecordIndex = 1 To .RecordCount
If currentRecordIndex <= limitRecords Or limitRecords < 0 Then
.ActiveRecord = currentRecordIndex
str = ""
For currentDataFieldIndex = 1 To .DataFields.Count
str = str & .DataFields(currentDataFieldIndex) & vbTab
Next
'Debug.Print str
End If
'.Included = True
'Debug.Print .Included
Next
End With
End Function
Is there a solution to know which records are selected by the user?
About my document: After some general computation, the data source is linked to the document using
Dim sql As String
sql = "SELECT * FROM `Sheet0$` "
sql = sql & "WHERE ((`" & photoPathHeader & "` > '') AND (`" & photoLastEditHeader & "` >= #" & Format(printFromDate, "yyyy-mm-dd") & "#)) "
sql = sql & "ORDER BY `klasse#name` ASC"
ThisDocument.MailMerge.OpenDataSource _
name:=ThisDocument.Path & "\" & ThisDocument.Variables("masterDataFileName"), _
SQLStatement1:=sql, _
ReadOnly:=True, LinkToSource:=True
a dialog where the user can select individual records for printing is shown. I used this code for that:
Application.Dialogs(wdDialogMailMergeRecipients).Display
And finally, the Mail Merge is executed using
ThisDocument.MailMerge.Execute
Many thanks in advance!

Answer 1

This Answer is based on the comments so far.
I do not get the problem with .Included here unless ThisDocument is the wrong document. However, since your loop code does not appear to throw an error when accessing other members of ThisDocument.MailMerge.DataSource it is not obvious what is wrong. However, I don't think you need to use .Included.
I see an immediate slowdown as soon as I try to access any of the .Datasource.DataFields items. I do not know why that is. There is a delay for each access, not just the first access for each record. The one idea I had is that as soon as you change the active record, Word refreshes the values of the merge fields in the main document, and that might cause a problem, particularly if Word needed to access the printer driver for some reason. But nothing I tried (e.g. change the View to Draft) changes that.
You don't really need .Included because you can iterate the records like this:
With ActiveDocument.MailMerge.DataSource
previousRecord = 0
.ActiveRecord = wdFirstRecord
While .ActiveRecord <> previousRecord
previousRecord = .ActiveRecord
Debug.Print .ActiveRecord ' (just lists the record number)
previousRecord = .ActiveRecord
.ActiveRecord = wdNextRecord
DoEvents ' advisable if you need to stop the code
Wend
If you need to iterate all the records then you need to use wdFirstDataSourceRecord and wdNextDataSourceRecord instead.
The only way I was able to speed up access to the data was to modify the document to include all the fields I wanted to list, then get the values from the document rather than from .DataSource.Datafields. Personally I do not think modify the Mail Merge main document is ideal - in particular, something might stop you from inserting material at the beginning, as I have done. But my test code (needs more error trapping etc. is like this):
Sub checkincluded()
Dim b As Word.Bookmark
Dim bVMMFC As Boolean
Dim bSFC As Boolean
Dim i As Integer
Dim previousRecord As Long
Dim p As Word.Paragraph
Dim r As Word.Range
With ActiveWindow.View
bSFC = .ShowFieldCodes
.ShowFieldCodes = False
End With
With ActiveDocument.MailMerge
bVMMFC = .ViewMailMergeFieldCodes
.ViewMailMergeFieldCodes = False
With .DataSource
Set r = ActiveDocument.Range(0, 0)
Set p = ActiveDocument.Range(0, 0).Paragraphs.Add
For i = 1 To .FieldNames.Count
If i > 1 Then
r.Text = vbTab
r.Start = p.Range.End - 1
r.End = p.Range.End - 1
End If
r.Fields.Add r, WdFieldType.wdFieldMergeField, .FieldNames(i), False
r.Start = p.Range.End - 1
r.End = p.Range.End - 1
Next
r.Start = 0
r.End = p.Range.End - 1
Set b = r.Bookmarks.Add("recorddata")
Set r = Nothing
previousRecord = 0
.ActiveRecord = wdFirstRecord
While .ActiveRecord <> previousRecord
previousRecord = .ActiveRecord
Debug.Print .ActiveRecord, b.Range.Text
previousRecord = .ActiveRecord
.ActiveRecord = wdNextRecord
DoEvents
Wend
b.Delete
Set b = Nothing
p.Range.Text = ""
Set p = Nothing
End With
.ViewMailMergeFieldCodes = bVMMFC
End With
ActiveWindow.View.ShowFieldCodes = bSFC
End Sub
Finally, it is probably worth pointing out that there are other ways to exclude records, e.g. using NEXT, NEXTIF, SKIP and SKIPIF fields. But that is perhaps another question.

Answer 2

Thanks to #yokki's answer, I was able to combine that with what I know and ended up with the following
Sub listIncluded()
Dim LastRecord As Long
With ActiveDocument.MailMerge.DataSource
' Storing the index of the last record for later use
.ActiveRecord = wdLastRecord
LastRecord = .ActiveRecord
.ActiveRecord = wdFirstRecord
Do
Debug.Print .ActiveRecord
DoEvents
If .ActiveRecord = LastRecord Then Exit Do
.ActiveRecord = wdNextRecord
Loop Until .ActiveRecord > LastRecord ' Note this will never be satisfied and the loop will always be exited via the Exit Do statement
End With
End Sub
I find the WdMailMergeActiveRecord enumeration a bit confusing but this works.
The original answer threw a 5853 Invalid parameter error on the wdNextRecord if the last included record had already been reached and was not equal to the last record overall (i.e. the last record was not included). I circumvented this issue by storing the index of the last record into a local variable and using that to check if the last included record was reached.
Thank you very much to everyone who helped!
As briefly pointed out in a comment, I already have a list of all the
data in the data source as an array since I also use it in other parts
of the script. I used the following statement for that
numRows = wks.Range("A1").CurrentRegion.Rows.Count
masterData = wks.Range("A1").CurrentRegion.Offset(RowOffset:=1).Resize(RowSize:=numRows).Value
wks refers to an Excel worksheet object.