splitting data under specific value after the sum of it - awk

Question

How do I split the input.txt after the sum of size column 1 under 80000
input.txt
11736 textDYN.txt
65736 textMV.txt
61812 textDYN_1.txt
11750 textGB.txt
$1 < 80000
total sum = 77472 under 80000 then, it will be output as output_001.txt
11736 textDYN.txt
65736 textMV.txt
total sum = 73562 under 80000 then, it will be output as output_002.txt
61812 textDYN_1.txt
11750 textGB.txt

Answer 1

$ cat tst.awk
{
sub(/\r$/,"")
sum += $1
}
(NR == 1) || (sum > 80000) {
close(out)
out = sprintf("output_%03d.txt",++cnt)
sum = $1
}
{ print $0 " > " out }
$ awk -f tst.awk file
11736 textDYN.txt > output_001.txt
65736 textMV.txt > output_001.txt
61812 textDYN_1.txt > output_002.txt
11750 textGB.txt > output_002.txt
Change print $0 " > " out to print > out when done testing.

Answer 2

If I understand how you want to split your files, you would need to handle the case where the sum of $1 is less than 80000 (by adding to sum), the case where it is more than 80000 (updating to output to a new filename and resetting the sum) and a third rule that writes to the current filename.
You could do something like:
awk 'BEGIN {sum=0; cnt=1; fn=sprintf("output_%03d.txt", cnt++)}
sum < 80000 {sum+=$1}
sum >= 80000 {fn=sprintf("output_%03d.txt", cnt++); sum=0}
{print $0 > fn}
' file
An example using your input data in file would be:
$ awk 'BEGIN {sum=0; cnt=1; fn=sprintf("output_%03d.txt", cnt++)}
> sum < 80000 {sum+=$1}
> sum >= 80000 {fn=sprintf("output_%03d.txt", cnt++); sum=0}
> {print $0 > fn}
> ' file
Resulting Files
$ cat output_001.txt
11736 textDYN.txt
65736 textMV.txt
$ cat output_002.txt
61812 textDYN_1.txt
11750 textGB.txt
If that isn't what you were attempting, please let me know and I'm happy to help further.