Trying to click a download button on Chrome using Selenium Type Library. The code below is one that I picked up off the boards but I am receiving a Syntax Error
Sub Test()
Dim bot
Set bot = CreateObject("Selenium.WebDriver")
bot.Start "Chrome", "https://www.afterpaytouch.com"
bot.get "/results-reports"
bot.findElement(By.linkText("https://www.afterpaytouch.com/images/28082019-FY2019-Results-Presentation.pdf")).click()
End Sub
I would add a reference to Selenium Type Library in VBE > Tools > References then use early bound reference, full url and apply VBA selenium basic syntax to find link by css and click
Option Explicit
Public Sub Test()
Dim bot As WebDriver
Set bot = New ChromeDriver
With bot
.Start "Chrome"
.get "https://www.afterpaytouch.com/results-reports"
.FindElementByCss("[href='https://www.afterpaytouch.com/images/28082019-FY2019-Results-Presentation.pdf']").Click
Stop '<delete me later
End With
End Sub
Related
I am trying to print a webpage using selenium in VBA. I want the bot to be able to press control+P and then Enter on the printing dialog but keep getting an object required error. Anyone have any ideas?
Sub printing()
Dim bot As New WebDriver, controlP As Variant, enter As Variant
bot.Start "chrome", ""
bot.Get "https://www.google.com/"
controlP = (Keys.Control & "p")
enter = (Keys.enter)
bot.FindElementByXPath("/html").SendKeys (conrolP)
bot.FindElementByXPath("/html").SendKeys (enter)
End sub
I am not sure the approach you are trying is the way to achieve your goal. However, here are some points:
I think the relevant xpath should be //html.
Use Option Explicit as first line of your module code; You have a typo with conrolP which Option Explicit would have alerted you to as an undeclared variable.
You also don't need those () with SendKeys.
I've created a script in vba in combination with selenium to parse the first headline from this webpage. Most of the times my script throws this error timeout or this error Run-time error 21; Application defined or Object defined error while sometimes it works flawlessly. As the page takes too much time to load it's content, I suppose I'm having one of the side effect of a slow loading page, so I wish to disable images from that page.
I've tried with:
Sub TestSelenium()
Const URL$ = "https://www.marketscreener.com/"
Dim driver As Object, post As Object
Set driver = New ChromeDriver
driver.get URL
Set post = driver.FindElementByCss(".une_title")
MsgBox post.Text
driver.Quit
End Sub
When I go for python selenium binding, I can use this option to disable images:
option = webdriver.ChromeOptions()
chrome_prefs = {}
option.experimental_options["prefs"] = chrome_prefs
chrome_prefs["profile.default_content_settings"] = {"images": 2}
chrome_prefs["profile.managed_default_content_settings"] = {"images": 2}
driver = webdriver.Chrome(options=option)
I know there are options to set different preferences in vba but in case of disabling images I can't find any proper way to set them:
driver.SetPreference
driver.AddArgument
How can I set chrome preferences in vba selenium to let the page load quickly without images?
To disable images from that page, this is how you can set the preference within vba selenium bindings:
driver.SetPreference "profile.managed_default_content_settings.images", 2
Your script looks like the following when you implement the above suggestion:
Sub TestSelenium()
Const URL$ = "https://www.marketscreener.com/"
Dim driver As Object, post As Object
Set driver = New ChromeDriver
driver.SetPreference "profile.managed_default_content_settings.images", 2
driver.get URL
Set post = driver.FindElementByCss(".une_title")
MsgBox post.Text
Stop
driver.Quit
End Sub
You could always try running it headless? That should remove any delay associated with image loading.
driver.AddArgument "--headless"
I'm trying to click on the Load More button located at the bottom of the left window of this webpage using vba in combination with selenium but the script always throws timeout error pointing at this .Get Url line. Although it seems I've defined an accurate xpath to locate the element, I can't think further as to what I should do now to achieve the same.
How can I click on that Load More button?
Sub ClickOnLoadMore()
Const Url$ = "http://www.ratemyprofessors.com/search.jsp?queryoption=TEACHER&queryBy=schoolDetails&schoolID=457&schoolName=James+Madison+University&dept=select"
Dim driver As New ChromeDriver, post As Object
With driver
.Get Url
Set post = .FindElementByXPath("//div[contains(.,'Load More')]")
.ExecuteScript "arguments[0].scrollIntoView();", post
post.Click
End With
End Sub
I see two "Load More" buttons. Both are matched by "//div[contains(.,'Load More')]". The first one is hidden. You need to handle second one.
Try this XPath
"//div[#class='content' and . = 'Load More']"
At least for me there were a couple of banners to dismiss as well as scrolling. There was no problem with the get line
Option Explicit
Public Sub ClickOnLoadMore()
Const Url$ = "http://www.ratemyprofessors.com/search.jsp?queryoption=TEACHER&queryBy=schoolDetails&schoolID=457&schoolName=James+Madison+University&dept=select"
Dim driver As New ChromeDriver, post As Object
With driver
.get Url
If .FindElementsByCss(".close-notice.close-this").Count > 0 Then
.FindElementByCss(".close-notice.close-this").Click
End If
.SwitchToFrame .FindElementByCss("[id^='spout-unit-iframe']")
With .FindElementByCss("#spout-ads #spout-header-close")
.ScrollIntoView
.Click
End With
.SwitchToDefaultContent
.ExecuteScript "document.querySelector('.result-list [onclick*=LoadMore]').scrollIntoView(true);" & _
"window.scrollBy(0, -(window.innerHeight - this.clientHeight) / 2);"
.FindElementByCss(".result-list [onclick*=LoadMore]").Click
Stop '<== Delete me later
'other code
.Quit
End With
End Sub
So I am tryin to create a Script that will automatically login for me on this website:
https://teespring.com/login
This is my script so far:
Sub openBrowser()
'Open new browser
Set driver = New Selenium.ChromeDriver
'Navigate to Website
urlWebsite = "https://teespring.com/login"
driver.Get urlWebsite
So I have tried to enter my username with the following lines of code:
driver.FindElementByCss("").sendKeys Username
But I got an error saying element not visible
Is there any way I can still automate the login process?
thanks for your help and if you need further information I will try my best to as I am still learning how to handle vba selenium :-)
It is not visible because it is inside a form.
You need to access via form:
Option Explicit
Public Sub EnterInfo()
Dim d As WebDriver
Set d = New ChromeDriver
Const URL = "https://teespring.com/login"
With d
.Start "Chrome"
.get URL
With .FindElementByClass("js-email-login-form")
.FindElementByCss("input[name=email]").SendKeys "myEmail"
.FindElementByCss("input[name=password]").SendKeys "myPassWord"
.FindElementByCss("input[type=submit]").Click
End With
Stop '<== Delete me after inspection
.Quit
End With
End Sub
I saw a similar thread on Java but I am not familiar with that language so need a solution for VBA- suppose I want to press ctrl+A to select all content in a website using selenium:
Private Sub CommandButton1_Click()
Dim shell: Set shell = CreateObject("WScript.Shell")
Dim driver As New SeleniumWrapper.WebDriver
driver.Start "firefox", "http://www.espnfc.com/gamecast/statistics/id/376930 /statistics.html"
driver.setImplicitWait 5000
driver.Open "/"
shell.SendKeys "^a"
End sub
However this only highlights the URL. What is the best way to select all the content in the webpage and then copy it (ctrl +a and ctrl+ c)? ALso are there any references I need?
I've been looking for a good guide to selenium keys on google but have been struggling so far...
Have you tried .getBodyText? I tested it once and it worked fine:
Private Sub CommandButton1_Click()
Dim shell: Set shell = CreateObject("WScript.Shell")
Dim driver As New SeleniumWrapper.WebDriver
dim Body as string
driver.Start "firefox", "http://www.espnfc.com/gamecast/statistics /id/376930 /statistics.html"
driver.setImplicitWait 5000
driver.Open "/"
Body=driver.getBodyText
End sub
You can then 'paste' into a spreadsheet via cells(1,1)=Body or back into a webpage element via driver.findElementById("ElementNameHere").SendKeys Body