How can I calculate the next birthday programmatically - vb.net

Question

I have a data table with a date-of-birth column.
I would want to split the date apart and change the year part with today.year which is current year.
Below is my code:
Dim birthda As New SqlDataAdapter(birthcmd)
Dim birthdt As New DataTable
birthda.Fill(birthdt)
For Each rw As DataRow In birthdt.Rows
Dim dob As String = rw.Item(3)
Dim mdat As Date = FormatDateTime(dob, DateFormat.ShortDate)
Dim bday As Date = (Date.Today.Year & mdat.Month & mdat.Day)
Dim yers As Integer = DateDiff(DateInterval.Year, mdat.Date, Today.Date)
Dim moths As Integer = DateDiff(DateInterval.Month, mdat.Date, Today.Date)
Dim dys As Integer = DateDiff(DateInterval.Day, mdat.Date, Today.Date)
but I get this error:
Conversion from string "2019715" to type 'Date' is not valid.
Description: An unhandled exception occurred during the execution of the current web request. Please review the stack trace for more information about the error and where it originated in the code.
Exception Details: System.InvalidCastException: Conversion from string "2019715" to type 'Date' is not valid.
Source Error:
Line 149:
Line 150: Dim bday As Date = (Date.Today.Year & mdat.Month & mdat.Day)

Answer 1

VB.net is very peculiar when it comes to String to Date conversion.
I would recommend converting the Date from the individual components like this :
Dim bday as Date = New Date(Date.Today.Year, mdat.Month, mdat.Day)
Or as stated in the comments try using VB.Net DateTime
Dim bday as New DateTime(Date.Today.Year, mdat.Month, mdat.Day, 0, 0, 0)

Answer 2

thank you i think I have figured it out this is what i did. I calculated for the age with respect to current year and added the result to the year part of the date of birth.
here is the code
For Each rw As DataRow In birthdt.Rows
Dim dob As DateTime = rw.Item(2)
Dim mdat As Date = FormatDateTime(dob, DateFormat.ShortDate)
Dim yers As Integer = DateDiff(DateInterval.Year, mdat.Date, Today.Date)
Dim moths As Integer = DateDiff(DateInterval.Month, mdat.Date, Today.Date)
Dim dys As Integer = DateDiff(DateInterval.Day, mdat.Date, Today.Date)
Dim ndob As Date = (DateAdd(DateInterval.Year, yers, mdat))
Dim yers2 As Integer = DateDiff(DateInterval.Year, ndob.Date, Today.Date)
Dim moths2 As Integer = DateDiff(DateInterval.Month, ndob.Date, Today.Date)
Dim dys2 As Integer = DateDiff(DateInterval.Day, ndob.Date, Today.Date)

Answer 3

I am basing this on what you wrote in a comment:
want to check those who have upcoming birthdays for a particular week.
It is fiddly to deal with leap years and dates which might be in the next year, but I think I've got all the cases covered here.
I made a table "Pets" in SQL Server with columns "Name" and "DOB", and put some data in.
I made a new Windows Forms project and added a multi-line textbox to Form1, and used this code:
Imports System.Data.SqlClient
Imports System.Text
Public Class Form1
Sub ShowUpcomingBirthdays()
Dim csb As New SqlConnectionStringBuilder With {.DataSource = ".\SQLEXPRESS", .InitialCatalog = "Testing", .IntegratedSecurity = True}
Dim birthdt As New DataTable()
Dim sql = "SELECT [Name], [DOB] FROM [Pets]"
Using conn As New SqlConnection(csb.ConnectionString)
Using sqlCmd As New SqlCommand(sql, conn)
Dim da As New SqlDataAdapter With {.SelectCommand = sqlCmd}
da.Fill(birthdt)
End Using
End Using
Dim matchEarliest = DateTime.Today
Dim matchLatest = matchEarliest.AddDays(8)
Dim sb As New StringBuilder ' somewhere to save the matching data
For Each r As DataRow In birthdt.Rows
Dim dob = Convert.ToDateTime(r.Item("DOB"))
' Allow for leap years by transferring the birthday to 1st March - some countries would use 28th February.
If DateTime.IsLeapYear(dob.Year) AndAlso Not DateTime.IsLeapYear(matchEarliest.Year) AndAlso dob.Month = 2 AndAlso dob.Day = 29 Then
dob = dob.AddDays(1)
End If
Dim nextBirthday = New DateTime(matchEarliest.Year, dob.Month, dob.Day)
If dob.Month <= matchEarliest.Month AndAlso dob.Day < matchEarliest.Day Then
' birthday has already happened this calendar year, make it next year
nextBirthday = nextBirthday.AddYears(1)
End If
If nextBirthday >= matchEarliest AndAlso nextBirthday < matchLatest Then
' the record is in the required range
sb.AppendLine(CStr(r.Item("Name")) & " " & dob.ToString("ddd dd MMMM"))
End If
Next
TextBox1.Text = sb.ToString()
End Sub
Private Sub Form1_Load(sender As Object, e As EventArgs) Handles MyBase.Load
ShowUpcomingBirthdays()
End Sub
End Class
It includes birthdays which happen "today" (you might not want to miss that), but you could
Dim matchEarliest = DateTime.Today.AddDays(1)
Dim matchLatest = matchEarliest.AddDays(7)
if you didn't want to include today.

Answer 4

I made a little class called Employee (it is at the bottom of the code). This answer is a bit similar to #AndrewMorton. I broke up the Sub into several functions that can be altered to suit without breaking the rest.
Private Sub DisplayUpcomingBirthdays()
Dim lstBirthdays As New List(Of Employee)
Dim dt = RetrieveBirthdays()
For Each rw As DataRow In dt.Rows
Dim CurrentYearBirthday As Date = GetCurrentYearBD(CDate(rw.Item("Birthdate")))
If IsBDThisWeek(CurrentYearBirthday) Then
lstBirthdays.Add(New Employee(CurrentYearBirthday, rw.Item("Name").ToString))
End If
Next
Dim SortedList = SortByBirthdays(lstBirthdays)
ListBox1.DataSource = SortedList
End Sub
Private Function RetrieveBirthdays() As DataTable
Dim query = "Select Name, Birthdate From Employes;"
Dim birthdt As New DataTable
Using cn As New SqlConnection("YourConnectionString")
Using cmd As New SqlCommand(query, cn)
cn.Open()
birthdt.Load(cmd.ExecuteReader)
End Using
End Using
Return birthdt
End Function
Private Function GetCurrentYearBD(BirthDate As Date) As Date
Dim Day As Integer = BirthDate.Day
Dim Month As Integer = BirthDate.Month
Dim Year As Integer = Now.Year
'Bithday is celebrated on the 28th when it is not a leap year
If Month = 2 AndAlso Day = 29 AndAlso Not DateTime.IsLeapYear(Year) Then
Day = 28
End If
Return New DateTime(Year, Month, Day)
End Function
Private Function IsBDThisWeek(BD As Date) As Boolean
Dim Tomorow = Now.AddDays(1)
Dim WeekFromNow = Now.AddDays(7)
If BD >= Tomorow AndAlso BD <= WeekFromNow Then
Return True
End If
Return False
End Function
Private Function SortByBirthdays(Employees As List(Of Employee)) As List(Of Employee)
Dim lst = (From emp In Employees
Order By emp.Birthdate
Select emp).ToList
Return lst
End Function
Public Class Employee
Public Property Birthdate As Date
Public Property Name As String
Public Sub New(BD As Date, eName As String)
Birthdate = BD
Name = eName
End Sub
Public Overrides Function ToString() As String
Return $"{Name}, {Birthdate.ToString("MMMM dd")}"
End Function
End Class