Find and Replace Single Digit numbers in MS Word - vba

Question

I am trying to locate single-digit numbers in MS Word (1-9) and replace it with word i.e. (1 = one, 2 = two). The current code replaces two-digit numbers and above. As of now, the only solution I can think of is to add spaces before and after the specific number but it is not that accurate.
Here is the code that I am using. TIA
Sub Single_Number()
Dim myDict: Set myDict = CreateObject("Scripting.Dictionary")
myDict("[1]{1}") = "one"
myDict("[2]{1}") = "two"
myDict("[3]{1}") = "three"
myDict("[4]{1}") = "four"
myDict("[5]{1}") = "five"
myDict("[6]{1}") = "six"
myDict("[7]{1}") = "seven"
myDict("[8]{1}") = "eight"
myDict("[9]{1}") = "nine"
Dim msword As Document, xWarp As Integer
For Each msword In Documents
msword.Activate
For myLoop = 0 To myDict.Count - 1
change_words myDict.Keys()(myLoop), myDict.Items()(myLoop)
Next
Next msword
End Sub
Function change_words(ByVal findWord, ByVal replaceWord)
If Selection.Type = wdSelectionIP Then
ActiveDocument.Range(0, 0).Select
xWarp = wdFindContinue
Else
xWarp = wdFindStop
End If
With Selection.Find
.ClearFormatting
.Text = findWord
.Replacement.Text = replaceWord
.Forward = True
.Forward = True
.Wrap = xWarp
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchAllWordForms = False
.MatchSoundsLike = False
.MatchWildcards = True
.Execute Replace:=wdReplaceAll
End With
End Function

Answer 1

Using the follow on string wasn't quite the best answer. The code below does the trick If and only if you only want to search in the main content of the document and your single digit numbers are preceded by a Space. If you are in the unfortunate position of having a single digit as the first character in a paragraph this code won't catch that issue. I'll leave it as an exercise to the reader as to how to modigy the () to include things such a paragraph markers.
The code below has been tested with
This 1 is 2 some 8 text 9. This is some7 more6 5 text
which is correctly converted as
This One is Two some Eight text Nine. This is some7 more6 Five text
This is the code
Sub ReplaceSingleNumbersWithText()
' Set up a search term for a single digit where the single digit is preceded
' by a space and followed by a character that is not a number or a letter
Const DIGIT_SEARCH As String = "( )([XXX]{1})([!0-9a-zA-Z])"
Dim myDigitAsWord As Variant
Dim mySearchDoc As Word.Document
Dim myIndex As Long
Dim myFindText As String
Dim myReplaceText As String
myDigitAsWord = Split("Zero,One,Two,Three,Four,Five,Six,Seven,Eight,Nine", ",")
For Each mySearchDoc In Word.Application.Documents
With mySearchDoc.StoryRanges(wdMainTextStory)
With .Find
.ClearFormatting
.Forward = True
.Wrap = wdFindContinue
.Format = False
.MatchCase = False
.MatchWholeWord = False
.MatchAllWordForms = False
.MatchSoundsLike = False
.MatchWildcards = True
End With
For myIndex = 0 To UBound(myDigitAsWord)
myFindText = Replace(DIGIT_SEARCH, "XXX", CStr(myIndex))
myReplaceText = "\1" & myDigitAsWord(myIndex) & "\3"
.Find.Execute FindText:=myFindText, replacewith:=myReplaceText, Replace:=wdReplaceAll
Next
End With
Next
End Sub