How to fix Loop Error, when using nestled If - vba

Question

I have written a piece of code, that is meant to check if the value entered is a date or not. That part works fine, but when I added what I thought would have been some validation (such as length of the string entered and if the date was before or today) it becomes an infinite loop that I can not escape.
I have tried the code with out the loop, and it behaves as expected, however when I combine the two the infinite loop returns.
'Checks if the value entered is in a 10 digit date format, after today
Do Until IsDate(DateOfJob)
DateOfJob = InputBox("What is the date the work is to be carried out on ? DD/MM/YYYY")
If Len(DateOfJob) <> 10 Then
DateOfJob = "NotEnoughCharacters"
ElseIf DateOfJob <= Date Then
DateOfJob = "Today"
End If
Loop
I would have expected that the code would have entered the loop, collected the value DateOfJob, then run the test to see if it was
Exactly 10 characters long
Before or today's date
At any point, if it did not pass those two tests, the DateOfJob would be give a text value, which would cause the final IsDate test to fail.
However, I feel it is being passed text regardless of what is entered, and therefor failing the test completely.
Thanks in advance for any help.

Answer 1

The length of the input string makes no difference: either you're looking at a date, or you're not: you want the rest of your code to work with the Date value, not the String representation that the user provided.
See if this works for you:
Public Function GetValidDate() As Variant '/Date
Dim isValid As Boolean
Do While Not isValid
Dim userInput As Variant
userInput = VBA.InputBox(...)
' if user cancelled the prompt; we better not prompt again:
If VarType(userInput) = vbBoolean Then
'if we don't assign the result, we yield a Variant/Empty:
Exit Function
End If
If IsDate(userInput) Then
Dim dateValue As Date
dateValue = CDate(userInput) '<~ we know it's valid at this point
isValid = dateValue > VBA.DateTime.Date
End If
Loop
GetValidDate = dateValue
End Function
Use:
'NOTE: As Date would be a *type mismatch* error if GetValidDate is Variant/Empty.
Dim jobStartDate As Variant
jobStartDate = GetValidDate
If Not IsDate(jobStartDate) Then Exit Sub
Don't trap the user into a loop they can't get out of without providing a valid input value - an InputBox has a Cancel button, and the user will expect it to cancel the operation: don't deny them that ability - gracefully handle it instead.

Answer 2

Thanks for everyone's input.
I went with Mathieu Guindon solution in the end, and just modified it slightly.
Nice little bit of code he wrote :)
Do While Not isValid
Dim userInput As Variant
userInput = VBA.InputBox("What is the date the work is to be carried out on ? DD/MM/YYYY")
' if user cancelled the prompt; we better not prompt again:
If VarType(userInput) = vbBoolean Then
'if we don't assign the result, we yield a Variant/Empty:
End
End If
If IsDate(userInput) Then
Dim dateValue As Date
dateValue = CDate(userInput) '<~ we know it's valid at this point
isValid = dateValue > VBA.DateTime.Date
End If
DateOfJob = dateValue
Loop