Split a file after a certain number of unique entries - awk

Question

Given a tab-delimited file:
A 12380
A 123801
A 1209
A 2035
A 4930
A 2903
B 2085
B 203801
B 240083
B 12308
B 12399
C 120303
C 1238058
C 235
D 55674
D 99683
D 2391095
D 12958
D 23804
D 5769
E 479903
E 28075
E 2310
E 6784
F 4789
F 23458
F 8976
G 9007
H 1203
H 12909
I want to split this after a certain number of unique entries have been seen - from a specific column. As an example, split the above file after every 3 unique entries in the first column. Producing 3 files:
A 12380
A 123801
A 1209
A 2035
A 4930
A 2903
B 2085
B 203801
B 240083
B 12308
B 12399
C 120303
C 1238058
C 235
D 55674
D 99683
D 2391095
D 12958
D 23804
D 5769
E 479903
E 28075
E 2310
E 6784
F 4789
F 23458
F 8976
G 9007
H 1203
H 12909
I have this so far:
awk -F"\t" 'BEGIN { count=0; filename=1 }; x[$1]++==0 {count++}; count==3 { count=1; filename++}; {print >> filename".txt"; close(filename".txt");}' file
However when running this on the terminal, I get the error:
awk: syntax error at source line 1
context is
BEGIN { count=0; filename=1 }; x[$1]++==0 {count++}; count==4 { count=1; filename++}; {print >> >>> filename".txt" <<<
awk: illegal statement at source line 1
Why?
EDIT: Removing the ".txt" fixes this - however it is super slow. Any help?

Answer 1

Could you please try following(tested with given samples).
awk -v count=1 '
prev!=$1 && prev{
count++
delete a[prev]
}
count==4 && !a[$1]++{
count=1
print ""
}
{
prev=$1
}
1
' Input_file
Explanation:
awk -v count=1 ' ##Starting awk program here, mentioning variable count whose value is 1.
prev!=$1 && prev{ ##Checking condition where prev NOT equal to current $1 and variable prev is NOT NULL then do following.
count++ ##Increment variable count with 1 here.
delete a[prev] ##Deleting array a value whose index is prev variable here.
}
count==4 && !a[$1]++{ ##Checking condition if count==4 and array a does not have any previous occurrence of $1 then do following.
count=1 ##Setting value of count to 1 here.
print "" ##Printing NULL line here.
}
{
prev=$1 ##Setting variable prev to $1 of current line.
}
1
' Input_file ##Mentioning Input_file name here.
EDIT: To take output into output file try following.
awk -v count=1 -v file_count=1 '
BEGIN{
file=file_count".txt"
}
prev!=$1 && prev{
count++
delete a[prev]
}
count==4 && !a[$1]++{
count=1
close(file)
file_count++
file=file_count".txt"
}
{
prev=$1
}
{
print $0 > (file)
}
' Input_file

Answer 2

$ awk '$1!=(p""){p=$1;u++}
u>3{close(n++".txt");u=1}
{print >(n".txt")}' n=1 file
$ cat 1.txt
A 12380
A 123801
A 1209
A 2035
A 4930
A 2903
B 2085
B 203801
B 240083
B 12308
B 12399
C 120303
C 1238058
C 235
$ cat 2.txt
D 55674
D 99683
D 2391095
D 12958
D 23804
D 5769
E 479903
E 28075
E 2310
E 6784
F 4789
F 23458
F 8976
$ cat 3.txt
G 9007
H 1203
H 12909