System.Data.SqlClient.SqlException: Violation of PRIMARY KEY - sql

Question

I create a SQL Server database and I want to add some data in a particular table of that database. I use some textbox to input the data and an add button to complete. But when I tap the button the whole process was stopped and indicate an error in the DBSQL module which is shown below.
Here's my code:
Imports System.Data
Imports System.Data.SqlClient
Module DBSQLServer
Public con As New SqlConnection("Data Source=JOYALXDESKTOP\SQLEXPRESS;Initial Catalog=SaleInventory;Integrated Security=True")
Public cmd As New SqlCommand
Public da As New SqlDataAdapter
Public ds As New DataSet
Public dt As DataTable
Public qr As String
Public i As Integer
Public Function searchdata(ByVal qr As String) As DataSet
da = New SqlDataAdapter(qr, con)
ds = New DataSet
da.Fill(ds)
Return ds
End Function
Public Function insertdata(ByVal qr As String) As Integer
cmd = New SqlCommand(qr, con)
con.Open()
i = cmd.ExecuteNonQuery()
con.Close()
Return i
End Function
End Module
The error occurs on this line:
i = cmd.ExecuteNonQuery()
In the table, I have 5 columns:
ProID, ProName, ProDesc, ProPrice, ProStock
ProID is my primary key.
Here's my add button code to add the data into the database:
Private Sub Add_Click(sender As Object, e As EventArgs) Handles add.Click
If (isformvalid()) Then
qr = "Insert into tblProductInfo (ProName, ProDesc, ProPrice, ProStock) Values('" & nametext.Text & "','" & descriptiontext.Text & "','" & pricetext.Text & "','" & stocktext.Text & "')"
Dim logincorrect As Boolean = Convert.ToBoolean(insertdata(qr))
If (logincorrect) Then
MsgBox("Stock Added Successfully ...", MsgBoxStyle.Information)
Else
MsgBox("Something Wrong. Record Not Saved. Please Check and Try Again...", MsgBoxStyle.Critical)
End If
End If
End Sub
When my query is:
qr = "Insert into tblProductInfo (ProName, ProDesc, ProPrice, ProStock) Values('" & nametext.Text & "','" & descriptiontext.Text & "','" & pricetext.Text & "','" & stocktext.Text & "')"
The error is below :
System.Data.SqlClient.SqlException: 'Cannot insert the value NULL into column 'ProID', table 'SaleInventory.dbo.tblProductInfo'; column does not allow nulls. INSERT fails.
And when my query is:
qr = "Insert into tblProductInfo (ProID, ProName, ProDesc, ProPrice, ProStock) Values('" & idtext.Text & "','" & nametext.Text & "','" & descriptiontext.Text & "','" & pricetext.Text & "','" & stocktext.Text & "')" `
Then the error is:
System.Data.SqlClient.SqlException: 'Violation of PRIMARY KEY constraint 'PK_tblProductInfo'. Cannot insert duplicate key in object 'dbo.tblProductInfo'. The duplicate key value is (1).

Answer 1

This is because in tblProductInfo there is a row with ProID=1. You should code so that avoid this duplicate, for example you can first run a script to find the maximum of ProID in your table ("Select MAX(ProID) from tblProductInfo"), and run your query with MAX(ProID)+1.

Answer 2

Assuming you have corrected your database making the ProdID an identity field.
Notice that all interaction with the user interface is performed in the Form code. All interaction with the database is performed in the Module. Although you still need to Import System.Data (for the DataTable type) it is not necessay to Import System.Data.SqlClient in the Form. All validation is done in the Form.
In the Module code, the Using...EndUsing blocks ensure that your database objects are closed and disposed even if there is an error. I have demonstrated how to use parameters to avoid Sql injection but I had to guess at the datatypes. Check your database for the actual datatypes and adjust the SqlDbType and the parameter types and the validation code in the Form accordingly.
Connections are precious resources. Notice that the connection is opened at the last minute and closed and disposed by the End Using immediately after it is used by and .Execute...
Module DBSQLServer
Private conString As String = "Data Source=JOYALXDESKTOP\SQLEXPRESS;Initial Catalog=SaleInventory;Integrated Security=True"
'Example of how your search function might look.
Public Function searchdata(Name As String) As DataTable
Dim dt As New DataTable
Using cn As New SqlConnection()
Using cmd As New SqlCommand("Select * From tblProductInfo Where Name = #Name", cn)
cmd.Parameters.Add("#Name", SqlDbType.VarChar).Value = Name
cn.Open()
dt.Load(cmd.ExecuteReader)
End Using
End Using
Return dt
End Function
Public Function insertdata(Name As String, Description As String, Price As Decimal, Stock As Integer) As Integer
Dim i As Integer
Using cn As New SqlConnection(conString)
Using cmd As New SqlCommand("Insert into tblProductInfo (ProName, ProDesc, ProPrice, ProStock) Values(#Name,#Description, #Price, #Stock", cn)
With cmd.Parameters
.Add("#Name", SqlDbType.VarChar).Value = Name
.Add("#Description", SqlDbType.VarChar).Value = Description
.Add("#Price", SqlDbType.Decimal).Value = Price
.Add("#Stock", SqlDbType.Int).Value = Stock
End With
cn.Open()
i = cmd.ExecuteNonQuery
End Using
End Using
Return i
End Function
End Module
And in the form
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
'First check that text boxes for string parameters are filled in
If nametext.Text = "" OrElse descriptiontext.Text = "" Then
MessageBox.Show("Please fill in all text boxes.")
Return
End If
'Next check for valid numeric values
Dim price As Decimal
If Not Decimal.TryParse(pricetext.Text, price) Then
MessageBox.Show("The price must be a number.")
Return
End If
Dim stock As Integer
If Not Integer.TryParse(stocktext.Text, stock) Then
MessageBox.Show("Stock must be a whole number")
Return
End If
Dim retVal As Integer = DBSQLServer.insertdata(nametext.Text, descriptiontext.Text, price, stock)
If retVal = 1 Then
MessageBox.Show("Product successfully added.")
End If
End Sub
Private Sub Button2_Click(sender As Object, e As EventArgs) Handles Button2.Click
Dim dt = DBSQLServer.searchdata(txtSearch.Text)
DataGridView1.DataSource = dt
End Sub