How to dynamically add and manipulate multiple, unique pictureboxes in VB.NET? - vb.net

Question

I'm a high-school student making a basic game for an assessment.
The game makes baseballs fly across the screen at the player, who bats them away.
All baseballs are contained in pictureboxes, and I need to be able to make an infinite number of them which can be individually referenced and moved, all during runtime.
I'm currently adding and storing pictureboxes in dictionaries. However, whenever I create a new picturebox and add it to the form, it overrides any previously created pictureboxes on the form.
I need to find code that allows previously created pictureboxes to remain on the form while creating new ones.
For context, I have added the logic flow of my program below.
Current Program Logic
Sub that randomly determines whether the ball will spawn on the left, right, north or south sides of the screen.
Sub that based on the above result, sets up a new "baseball" picturebox by altering a blank variable.
Sub that adds this as the Value to a dictionary, with the Key a variable called ballNameNumber.
At the same time, a random number is set as the Value for a dictionary called ballVelocity, with Key ballNameNumber. This is multiplied by a variable called level, which increases as the game time increases.
So at this point, a ball has been created, with identical key names in 3 dictionaries that each store its picturebox values and speed.
Sub that randomly chooses 1 of 4 spawn locations, records the direction of the ball to a dictionary called ballDirection based on this value, then creates the ball at this location.
All these subs occur in this order per tick of a timer called tmrGameTime (interval 500), on a form called frmGame (size 700,700)
'Dictionaries used to log and describe the movement of the balls onscreen.
Dim spawnedBalls As Dictionary(Of Integer, PictureBox) = New Dictionary(Of Integer, PictureBox)
Dim ballVelocity As Dictionary(Of Integer, Integer) = New Dictionary(Of Integer, Integer)
Dim ballDirection As Dictionary(Of Integer, String) = New Dictionary(Of Integer, String)
'Variables used in the composition of dictionaries.
Dim ballNameNumber As Integer = 1
Dim numberOfBalls As Integer = 0
Dim level As Integer = 1
Dim ball As New Picturebox
'Turns on the game timer
Private Sub frmGame_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
tmrGameTime.Enabled = True
tmrGameTime.Start()
End Sub
'Sets values to the ball variable (must be done within a sub otherwise an error is dispayed)
Public Sub ballSetUpLeft(ByRef ballTemplate)
ballTemplate.SizeMode = PictureBoxSizeMode.StretchImage
ballTemplate.Width = 34
ballTemplate.Height = 29
ballTemplate.Top = 325
ballTemplate.Left = 55
ballTemplate.Image = My.Resources.Baseball_Sprite
End Sub
Public Sub ballSetUpRight(ByRef ballTemplate)
ballTemplate.SizeMode = PictureBoxSizeMode.StretchImage
ballTemplate.Width = 34
ballTemplate.Height = 29
ballTemplate.Top = 325
ballTemplate.Left = 593
ballTemplate.Image = My.Resources.Baseball_Sprite
End Sub
Public Sub ballSetUpTop(ByRef ballTemplate)
ballTemplate.SizeMode = PictureBoxSizeMode.StretchImage
ballTemplate.Width = 34
ballTemplate.Height = 29
ballTemplate.Top = 59
ballTemplate.Left = 333
ballTemplate.Image = My.Resources.Baseball_Sprite
End Sub
Public Sub ballSetUpBottom(ByRef ballTemplate)
ballTemplate.SizeMode = PictureBoxSizeMode.StretchImage
ballTemplate.Width = 34
ballTemplate.Height = 29
ballTemplate.Top = 574
ballTemplate.Left = 333
ballTemplate.Image = My.Resources.Baseball_Sprite
End Sub
'Generates a random speed for a spawned ball based on the level value.
Public Function generateBallSpeed(ByVal level) As Integer
Randomize()
Dim ans As Integer = (((Rnd() * 10) * level) + 1)
Return ans
End Function
'Logs the ball data into dictionaries
Public Sub createBall(ByRef spawnedBalls, ByRef ballVelocity, ByRef ballNameNumber, ByRef numberOfBalls, ByRef ballTemplate)
'Adds a new ball with name and ballTemplate values to the dictionary.
spawnedBalls.Add(ballNameNumber, ballTemplate)
Dim v As Integer = generateBallSpeed(level)
'Using the matching name, adds a velocity value to the ball
ballVelocity.Add(ballNameNumber, v)
End Sub
'Spawns ball at a specific location on the form.
Public Sub spawnBallAtPitcher()
Randomize()
Dim pitcher As Integer = Int((4 - 1 + 1) * Rnd() + 1)
Select Case pitcher
Case 1
Call ballSetUpLeft(ballTemplate)
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, ballTemplate)
ballDirection.Add(ballNameNumber, "Left")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
Case 2
Call ballSetUpRight(ballTemplate)
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, ballTemplate)
ballDirection.Add(ballNameNumber, "Right")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
Case 3
Call ballSetUpTop(ballTemplate)
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, ballTemplate)
ballDirection.Add(ballNameNumber, "Top")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
Case 4
Call ballSetUpBottom(ballTemplate)
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, ballTemplate)
ballDirection.Add(ballNameNumber, "Down")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
End Select
End Sub
'Repeatedly spawns balls
Private Sub tmrGameTime_Tick_1(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles tmrGameTime.Tick
Call spawnBallAtPitcher()
End Sub
End Class
I expect that the pictureboxes will appear in random order on my form, until four a visible at different points (as any further pictureboxes will be created on top of the previous). However, on picturebox is created and then jumps between spawn locations. No error messages are received.

Answer 1

Your problem is you're using only 1 reference of ball in your code. So each time you want to create another ball, you use replace the previous ball with your new ball. Change your code in the 4 procedures into functions then return the new ball.
'Sets values to the ball variable (must be done within a sub otherwise an error is dispayed)
Public Function ballSetUpLeft() As PictureBox
Dim newBall As New PictureBox
newBall.SizeMode = PictureBoxSizeMode.StretchImage
newBall.Width = 34
newBall.Height = 29
newBall.Top = 325
newBall.Left = 55
newBall.Image = My.Resources.Baseball_Sprite
Return newBall
End Function
Public Function ballSetUpRight() As PictureBox
Dim newBall As New PictureBox
newBall.SizeMode = PictureBoxSizeMode.StretchImage
newBall.Width = 34
newBall.Height = 29
newBall.Top = 325
newBall.Left = 593
newBall.Image = My.Resources.Baseball_Sprite
Return newBall
End Function
Public Function ballSetUpTop() As PictureBox
Dim newBall As New PictureBox
newBall.SizeMode = PictureBoxSizeMode.StretchImage
newBall.Width = 34
newBall.Height = 29
newBall.Top = 59
newBall.Left = 333
newBall.Image = My.Resources.Baseball_Sprite
Return newBall
End Function
Public Function ballSetUpBottom() As PictureBox
Dim newBall As New PictureBox
newBall.SizeMode = PictureBoxSizeMode.StretchImage
newBall.Width = 34
newBall.Height = 29
newBall.Top = 574
newBall.Left = 333
newBall.Image = My.Resources.Baseball_Sprite
Return newBall
End Function
Then change how you call the functions (used to be procedures) like this:
Select Case pitcher
Case 1
Dim newBall = ballSetUpLeft()
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, newBall)
ballDirection.Add(ballNameNumber, "Left")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
Case 2
Dim newBall = ballSetUpRight()
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, newBall)
ballDirection.Add(ballNameNumber, "Right")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
Case 3
Dim newBall = ballSetUpTop()
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, newBall)
ballDirection.Add(ballNameNumber, "Top")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
Case 4
Dim newBall = ballSetUpBottom()
Call createBall(spawnedBalls, ballVelocity, ballNameNumber, numberOfBalls, newBall)
ballDirection.Add(ballNameNumber, "Down")
ballNameNumber += 1
Me.Controls.Add(spawnedBalls.Item(ballNameNumber - 1))
End Select
Now your balls won't be replaced each time you want to create another ball. I leave the task to animate the balls and removing the balls when the pitcher hit the balls.
I tried to reduce redundancy in your code. The 3 dictionaries are replaced by a single dictionary which hold the ball information (id, direction, velocity and the picture). Use enumeration instead of hard-coded numbers for direction. Use Random class instead of Randomize() and Rnd() functions.
Public Class frmGame
'Dictionaries used to log and describe the movement of the balls onscreen.
Private balls = New Dictionary(Of Integer, Ball)
'Variables used in the composition of dictionaries.
Private random As New Random
Private lastBallID As Integer
Private Const level As Integer = 1
Private Sub frmGame_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
'Turns on the game timer
tmrGameTime.Enabled = True
tmrGameTime.Start()
End Sub
Private Sub tmrGameTime_Tick_1(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles tmrGameTime.Tick
'Repeatedly spawns balls
spawnBallAtPitcher()
End Sub
'Spawns ball at a specific location on the form.
Private Sub spawnBallAtPitcher()
lastBallID += 1
Dim pitcher As Direction = random.Next(4) + 1
Dim newBall = createBall(lastBallID, pitcher, random)
Controls.Add(newBall.Picture)
'Logs the ball data into dictionaries
balls.Add(lastBallID, newBall)
End Sub
'Create new ball, set its ID, direction, velocity and picture
Private Function createBall(ballID As Integer, direction As Direction, rnd As Random) As Ball
Return New Ball With {
.BallID = ballID,
.Direction = direction,
.Velocity = generateBallSpeed(level, rnd),
.Picture = generateBallPicture(direction)
}
End Function
'Generates a random speed for a spawned ball based on the level value.
Private Function generateBallSpeed(ByVal level As Integer, ByVal rnd As Random) As Integer
Return (rnd.Next(10) + 1) * level
End Function
'Generates a new picture of ball
Private Function generateBallPicture(direction As Direction) As PictureBox
Dim location = generatePictureLocation(direction)
Return New PictureBox With {
.SizeMode = PictureBoxSizeMode.StretchImage,
.Width = 34,
.Height = 29,
.Top = location.Y,
.Left = location.X,
.Image = My.Resources.Baseball_Sprite
}
End Function
'Generates a location for new picture of ball
Private Function generatePictureLocation(direction As Direction) As Point
Select Case direction
Case Direction.Left
Return New Point(55, 325)
Case Direction.Right
Return New Point(593, 325)
Case Direction.Top
Return New Point(333, 59)
Case Direction.Bottom
Return New Point(333, 574)
End Select
End Function
End Class
Public Enum Direction
Left = 1
Right
Top
Bottom
End Enum
Public Class Ball
Public Property BallID As Integer
Public Property Velocity As Integer
Public Property Direction As Integer
Public Property Picture As PictureBox
End Class