Display call transaction screen in a Splitter-container - abap

Question

I have a program which displays a splitter-container with two columns:
Left side displays a control tree (this is OK)
Right side should displays a custom TCode (not sure how to do this bit)
On double-click of a tree node, it calls a transaction which opens a screen, but it opens in a new window.
How to open the screen in the right-side window?
Minimal reproducible example:
Create the transaction code ZCALL_ZPRG1 via SE93, so that it calls the program ZPRG1
Create the program ZPRG1 (minimalist screen):
REPORT zprg1.
PARAMETERS test AS CHECKBOX.
Create the program ZPRG2 (splitter and tree):
REPORT zprg2.
CLASS lcl_app DEFINITION.
PUBLIC SECTION.
METHODS:
pbo,
on_node_double_click FOR EVENT node_double_click OF cl_gui_simple_tree.
DATA:
tree TYPE REF TO cl_gui_simple_tree,
itab TYPE TABLE OF mtreesnode,
splitter TYPE REF TO cl_gui_splitter_container.
ENDCLASS.
CLASS lcl_app IMPLEMENTATION.
METHOD pbo.
CHECK tree IS NOT BOUND.
CREATE OBJECT splitter
EXPORTING
parent = cl_gui_container=>screen0
rows = 1
columns = 2.
itab = VALUE #(
( node_key = '1'
text = 'Double-click me' ) ).
CREATE OBJECT tree
EXPORTING
parent = splitter->get_container( row = 1 column = 1 )
node_selection_mode = cl_gui_simple_tree=>node_sel_mode_single.
tree->add_nodes(
table_structure_name = 'MTREESNODE'
node_table = itab ).
SET HANDLER on_node_double_click FOR tree.
DATA events TYPE cntl_simple_events.
CALL METHOD tree->set_registered_events
EXPORTING
events = VALUE #( ( eventid = tree->eventid_node_double_click ) )
EXCEPTIONS
OTHERS = 4.
ENDMETHOD.
METHOD on_node_double_click.
CALL TRANSACTION 'ZCALL_ZPRG1'.
ENDMETHOD.
ENDCLASS.
DATA: app TYPE REF TO lcl_app.
PARAMETERS dummy.
INITIALIZATION.
CREATE OBJECT app.
AT SELECTION-SCREEN OUTPUT.
app->pbo( ).
AT SELECTION-SCREEN ON EXIT-COMMAND.
app->splitter->free( ).
Run ZPRG2
Double-click the tree node

Answer 1

In the SAP GUI, it is possible to mix screens of dynpro technology and GUI controls of the SAP Control Framework in these ways:
Screen and Docking Containers ; these containers may be displayed at any of the 4 sides of the screen
In these containers can be placed GUI controls (including splitter containers)
Screen containing a so-called Custom Container area in which can be placed GUI controls (including splitter containers)
Popups can be displayed over any dynpro screen or GUI control; those popups may also contain any (other) dynpro screen or GUI control; they are completely independent from the screen below. Popups may also be displayed over popups.
It is not possible to embed a dynpro screen inside a GUI control (including containers) in any manner.
So, in your case, the only solution is to use a docking container on the left of your dynpro screen. But only the program which displays the dynpro screen is allowed to "add" the docking container (i.e. CALL TRANSACTION or SUBMIT cannot be used).
Consequently, ZPRG2 must handle both your GUI control and a dynpro screen. You have two options to handle the dynpro screen:
Either ZPRG2 handles it (everything is done by ZPRG2, you don't need ZPRG1)
Or you only define a subscreen area inside the dynpro screen of ZPRG2, and you include a subscreen from ZPRG1 which handles all the initializations and interactions of the subscreen.
The second solution is recommended because it permits the Separation Of Concerns".
The code below is a minimal example to demonstrate how it could work, that will allow you to debug and understand better; there are so many things to explain that I prefer to let you ask questions in the comments (or new questions); be aware that many of the algorithm, statements and tricks below are not advised, I use them just because they are much shorter. You will end up with a much more complex program than this one.
Program ZPRG1 (right side, show/hide UI elements to react to double click at left side):
REPORT zprg1.
DATA display TYPE abap_bool VALUE abap_false.
SELECTION-SCREEN BEGIN OF SCREEN 0100 AS SUBSCREEN.
PARAMETERS test AS CHECKBOX.
SELECTION-SCREEN END OF SCREEN 0100.
AT SELECTION-SCREEN OUTPUT.
IF display = abap_false.
LOOP AT SCREEN.
screen-active = '0'.
MODIFY SCREEN.
ENDLOOP.
ENDIF.
FORM toggle_display.
IF display = abap_false.
display = abap_true.
ELSE.
display = abap_false.
ENDIF.
ENDFORM.
Program ZPRG2 (left side tree + handling of subscreen area at the right to include ZPRG1 screen):
REPORT zprg2.
DATA okcode TYPE syucomm. " global variable for dynpro 0200 "OKCODE" element
CLASS lcl_app DEFINITION.
PUBLIC SECTION.
METHODS:
pbo,
pai,
on_node_double_click FOR EVENT node_double_click OF cl_gui_simple_tree.
DATA:
tree TYPE REF TO cl_gui_simple_tree,
itab TYPE TABLE OF mtreesnode,
docking TYPE REF TO cl_gui_docking_container.
ENDCLASS.
CLASS lcl_app IMPLEMENTATION.
METHOD pbo.
SET PF-STATUS space. " <=== trick to activate buttons in the system toolbar
CHECK tree IS NOT BOUND.
CREATE OBJECT docking
EXPORTING
repid = sy-repid
dynnr = sy-dynnr
side = docking->dock_at_left
extension = 400 " pixels
EXCEPTIONS
OTHERS = 6.
itab = VALUE #(
( node_key = '1'
text = 'Double-click me' ) ).
CREATE OBJECT tree
EXPORTING
parent = docking
node_selection_mode = cl_gui_simple_tree=>node_sel_mode_single.
tree->add_nodes(
table_structure_name = 'MTREESNODE'
node_table = itab ).
SET HANDLER on_node_double_click FOR tree.
DATA events TYPE cntl_simple_events.
CALL METHOD tree->set_registered_events
EXPORTING
events = VALUE #( ( eventid = tree->eventid_node_double_click
appl_event = 'X' ) ) " <=== to trigger the PAI
EXCEPTIONS
OTHERS = 4.
ENDMETHOD.
METHOD on_node_double_click.
PERFORM toggle_display IN PROGRAM zprg1.
ENDMETHOD.
METHOD pai.
CASE okcode.
WHEN 'BACK' OR 'RW' OR '%EX'. " one of the exit buttons in system toolbar
docking->free( ). " free container and inner controls
SET SCREEN 0. " to return after the current CALL SCREEN
ENDCASE.
ENDMETHOD.
ENDCLASS.
START-OF-SELECTION.
DATA: app TYPE REF TO lcl_app.
CREATE OBJECT app.
CALL SCREEN 200.
MODULE status_0200 OUTPUT.
app->pbo( ).
ENDMODULE.
MODULE user_command_0200 INPUT.
app->pai( ).
ENDMODULE.
Dynpro 0200 of program ZPRG2:
The layout contains a huge subscreen area named SUBAREA, and the OKCODE element is to be assigned the name OKCODE (which is mapped to the global variable of ZPRG2 having the same name)
The flow logic contains this code:
PROCESS BEFORE OUTPUT.
MODULE status_0200.
CALL SUBSCREEN subarea INCLUDING 'ZPRG1' '0100'.
PROCESS AFTER INPUT.
CALL SUBSCREEN subarea.
MODULE user_command_0200.