Remove Line If It Contains Exact String From Line Of Another File - awk

Question

I have a large file and would like to remove any lines from the file that contain an exact string listed in another file. However, the string must match exactly (I'm sorry I don't know how to describe this better).
Here is the file:
one#email.com,name,surname,city,state
two#email.com,name,surname,city,state
three#email.com,name,surname,city,state
anotherone#email.com,name,surname,city,state
And here is the example list to filter with:
one#email.com
three#email.com
The desired output is:
two#email.com,name,surname,city,state
anotherone#email.com,name,surname,city,state
I have tried to do this using the following:
grep -v -f 2.txt 1.txt > 3.txt
However this produces the output:
two#email.com,name,surname,city,state
I assume it's doing this because "anotherone#email.com" contains "one#email.com". I've searched for a way to include beginning of the line, but not found anything suitable.
I'm open to doing in something other than grep too, I used grep because I couldn't figure it out any other way.

Answer 1

Assuming that your input file contains three#gmail.com not three#email.com (typo perhaps)
$ grep -vw -f 2.txt 1.txt
two#email.com,name,surname,city,state
anotherone#email.com,name,surname,city,state
-w, --word-regexp -
The expression is searched for as a word (as if surrounded by [[:<:]]' and[[:>:]]';

Answer 2

If you only like to print lines from first file that does not contains data from second file in the first field, then this should do:
$cat file
one#email.com,name,surname,city,state
two#email.com,name,surname,city,state
three#email.com,name,surname,city,state
anotherone#email.com,name,surname,city,state
$cat filter
one#email.com
three#email.com
awk -F, 'NR==FNR {a[$0]++;next} !($1 in a)' filter file
two#email.com,name,surname,city,state
anotherone#email.com,name,surname,city,state
For every line in the filter this creates an array a with the name and value to 1
Like a[one#email.com]=1 and a[three#email.com]=1
Then awk test line by line in the file against the array, giving
a[one#email.com]=1
a[two#email.com]=
a[three#email.com]=1
a[anotherone#email.com]=
Then print all line from the file without 1
two#email.com,name,surname,city,state
anotherone#email.com,name,surname,city,state

Answer 3

For this particular case -- process first file by building an associative array with filter lines being the index. In subsequent files, test if the given line is not in the array indexes -- the default action of a pattern is to print.
awk -F, -v OFS=, '
BEGIN { split("", m) }
NR==FNR { m[$0] = ""; next }
!($1 in m)
' filter.txt file.txt
But... if we are looking to filter any occurrence of the string anywhere in the line (an unconstrained exact match) we need to do something less clever and more brute-force:
awk '
BEGIN {
split("", m)
n=0
}
NR==FNR {
m[n++] = $0
next
}
{
for (i=0; i<n; ++i) {
if (index($0, m[i]))
next
}
print
}
' filter.txt file.txt
Note that if the filter contains non-printable characters (e.g. non-unix line endings), we would need to deal with them by filtering them out (e.g. with sub(/\r/, "")).