Does DM scripting have an equivalent to c++ pointers? - dm-script

Question

As the title asks. I am interested in knowing if the DM scripting language is capable of handling references and pointers, like you would find in c/c++ as *a and &a. I'm guessing the capability exists at some level, owing to the way inbuilt functions like fitgaussian() work. If this capability is open to the user, it would make it easier to code up some classes and functions I want to create.

Answer 1

Yes, it does and it actually is quite similar to C++.
(But the simplification of the script language obscures it a bit.)
I'm trying to shed some light on it:
All objects in DM (Image, TagGroup, Component, ROI, ImageDisplay, etc. ) are automatically and always passed by reference, not value.
You can see this in the following example code:
void ModifyImage( image imgTemp )
{
imgTemp = irow
}
Image img := RealImage( "Test", 4, 100, 100 )
img = icol
img.ShowImage()
OKDialog("Act!")
ModifyImage( img )
img.ShowImage()
The actual image img of the main script changes. The routine ModifyImage received and used a reference to the image object.
Hint: This is a very typical source for bugs when dealing with TagGroups. When one f.e. gets a tag from an image and then modifies it in a method, it changes the tag of the image!
In order to have methods not modify the provided parameter objects passed in by reference, one has to explicitly create a clone of the object first. For this reason, all the object-types in the scripting languages provide ...clone() commands.
void ModifyImage( image imgTemp )
{
imgTemp = irow
}
Image img := RealImage( "Test", 4, 100, 100 )
img = icol
img.ShowImage()
OKDialog("Act!")
ModifyImage( img.ImageClone() )
Now, the img variable of the main script is not changed. (Because we create a copy in memory, and then pass the reference to the copy.)
However, primitive types (string, number) are by default passed by value, not reference.
Again, this can be seen by a little example.
void ModifyString( string tempStr )
{
tempStr = "Changed"
}
string str = "Original"
Result("\n" + str )
OKDialog("Act!")
ModifyString( str )
Result(" --> " + str )
Here the variable str of the main script is not changed by ModifyString because the values was passed into tempStr, and not a reference. The same is true for number type variables.
If one wants to pass a primitive type by reference, this can be denoted with a & in the methods signature.
The example from above now modified:
void ModifyString( string &tempStr )
{
tempStr = "Changed"
}
string str = "Original"
Result("\n" + str )
OKDialog("Act!")
ModifyString( str )
Result(" --> " + str )
The & can also be used for non-primitive objects in DM, if the passed in pointer is allowed to be changed:
Here is an example for this. The method does not modify the provided image, but instead creates a new one and passes back the reference into the pointer.
void ModifyImage( image &imgTemp )
{
imgTemp := RealImage( "New Test" , 4, 200, 200 )
imgTemp = iradius
}
Image img := RealImage( "Test", 4, 100, 100 )
img = icol
img.ShowImage()
OKDialog("Act!")
ModifyImage( img )
img.ShowImage()
Finally: The * operator to denote pointers is never used in DM-scripting.