Conver Time from UTC to PST/PDT/CET and CEST with VBA - vba

Question

I have a cloumn (Col. A) of the time and date for one years based on UTC time as the follow format (in fact i have 30 mins Intervals) from first of the year until end of the year:
01.01.2019 00:00
01.01.2019 00:30
.
.
.
31.12.2019 11:00
31.12.2019 11:30
Now I want to convert the time from UTC to CET when it's winter Time and CEST when is Summer time (I want to have the information in Col.B). I could do it with Excel Formula Easily but as my file is big enough I have to use VBA code.
Do have any suggetion How can I do it? My problem is on switching summer time to winter time via versa.

Answer 1

Regarding the time zone conversion itself, Wikipedia says (https://en.wikipedia.org/wiki/Central_European_Summer_Time#Period_of_observation):
Since 1996, European Summer Time has been observed between 01:00 UTC
(02:00 CET and 03:00 CEST) on the last Sunday of March, and 01:00 UTC
on the last Sunday of October
If I'm reading that correctly, a datetime can only be CET if it:
is before (<) the last Sunday of March at 01:00 UTC (i.e. when CEST begins)
or is on or after (>=) the last Sunday of October at 01:00 UTC (i.e. when CET begins)
It's not clear to me what your source data is like. (It looks like two datetimes delimited by a space, meaning each row actually contains a string. If this is true, you'll likely need to split the string into two strings along the delimiting space, then convert the two strings into two datetimes. This can probably be done with LEFT, RIGHT, DATEVALUE functions in VBA.)
To give you an example, I've filled range A1:A17520 of my worksheet "Sheet1" with datetimes at half-hour intervals (similar to what you've shown):
and I then use the code below to convert my values in column A (and put the converted values in column B of the same sheet):
Option Explicit
Private Sub ConvertUtcDatesInColumnAToCETorCEST()
Dim sourceSheet As Worksheet
Set sourceSheet = ThisWorkbook.Worksheets("Sheet1")
Dim lastSourceRow As Long
lastSourceRow = sourceSheet.Cells(sourceSheet.Rows.Count, "A").End(xlUp).Row
Dim datesFromSheet() As Variant
datesFromSheet = sourceSheet.Range("A1", sourceSheet.Cells(lastSourceRow, "A"))
Dim outputArray() As Date
ReDim outputArray(1 To UBound(datesFromSheet, 1), 1 To 1)
Dim rowIndex As Long
For rowIndex = LBound(datesFromSheet, 1) To UBound(datesFromSheet, 1)
outputArray(rowIndex, 1) = ConvertUtcDateTimeToCETorCEST(datesFromSheet(rowIndex, 1))
Next rowIndex
sourceSheet.Range("B1").Resize(UBound(outputArray, 1), UBound(outputArray, 2)).Value = outputArray
End Sub
Private Function LastSundayOfSomeMonthAndYear(ByVal someMonth As Long, ByVal someYear As Long) As Date
Dim lastDateInMonth As Date
lastDateInMonth = Application.EoMonth(DateSerial(someYear, someMonth, 1), 0)
Dim lastSundayInMonth As Date
LastSundayOfSomeMonthAndYear = lastDateInMonth - Weekday(lastDateInMonth, vbSunday) + 1
End Function
Private Function ConvertUtcDateTimeToCETorCEST(ByVal someUtcDateTime As Date) As Date
Dim startOfCESTinUTC As Date
startOfCESTinUTC = LastSundayOfSomeMonthAndYear(someMonth:=3, someYear:=Year(someUtcDateTime)) + TimeSerial(1, 0, 0)
Dim endOfCESTinUTC As Date
endOfCESTinUTC = LastSundayOfSomeMonthAndYear(someMonth:=10, someYear:=Year(someUtcDateTime)) + TimeSerial(1, 0, 0)
Dim isCET As Boolean
isCET = someUtcDateTime < startOfCESTinUTC Or someUtcDateTime >= endOfCESTinUTC ' Not sure if end is inclusive or exclusive
Dim hoursToAdd As Date
If isCET Then hoursToAdd = TimeSerial(2, 0, 0) Else hoursToAdd = TimeSerial(3, 0, 0)
ConvertUtcDateTimeToCETorCEST = someUtcDateTime + hoursToAdd
End Function
which gives me something like this:
Something to note is that this approach is quite inefficient for a few reasons:
The variables startOfCESTinUTC and endOfCESTinUTC are re-calculated every single time the function ConvertUtcDateTimeToCETorCEST is invoked (~17.5k times in my case). Since all of our datetimes are during the same year, the values of startOfCESTinUTC and endOfCESTinUTC will not change (so really the variables startOfCESTinUTC and endOfCESTinUTC should be determined just once, before the For loop).
If you know in advance and for sure that your data is sorted and is at half-hour intervals, you can do some maths and work out on which row CEST must begin on and end on. With that knowledge, you no longer need to check if the datetime is CET or CEST inside the For loop. If you use three For loops (loop 1: first row to row CET ends on, loop 2: row CEST starts on to row CEST ends on, loop 3: row CET starts on to last row), you can convert all values to CET (loop 1, loop 3) and CEST (loop 2) without actually checking what the value is. This makes the code more specialised (and faster), but also less reusable.
Modern computers are (relatively) fast. The code above converted 17.5k datetimes for me in <2 seconds on my machine. You may also want to check if the code handles the boundaries of CET and CEST correctly.