Update database with dataviewgrid on joined query - sql

Question

Update my SQL Server with info provided by dataviewgrid changes, mainly a checkbox / bit field.
I can populate my dataviewgrid and I can even make it update if i only use a single table, the problem is I want my query to have three tables joined, just to display information.
I've tried to replicate some tutorials and make changes of my own but it just doesn't seems to click.
It has been a while since I've coded in VB so there's also that.
What I have so far:
Imports System.Data.SqlClient
Public Class Form1
Dim myDA1 As SqlDataAdapter
Dim myDataSet1 As DataSet
Dim myDA2 As SqlDataAdapter
Dim myDataSet2 As DataSet
Private Sub Form1_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load
Dim con2 As SqlConnection = New SqlConnection("Data Source=CONNECTION STRING WORKS FINE")
Dim cmd2 As SqlCommand = New SqlCommand("SELECT x1,y2,z1 from a inner join b where a.x1=b.x2", con2)
con2.Open()
myDA2 = New SqlDataAdapter(cmd2)
Dim builder2 As SqlCommandBuilder = New SqlCommandBuilder(myDA2)
myDataSet2 = New DataSet()
myDA2.Fill(myDataSet2, "MyTable2")
DataGridView2.DataSource = myDataSet2.Tables("MyTable2").DefaultView
con2.Close()
con2 = Nothing
End Sub
Private Sub DataGridView2_CellContentClick(sender As Object, e As DataGridViewCellEventArgs) Handles DataGridView2.CellContentClick
Me.Validate()
Me.myDA2.Update(Me.myDataSet2.Tables("MyTable2"))
Me.myDataSet2.AcceptChanges()
End Sub
End Class
It's updating on a basic query, yes, but i need to make it update on a join query.

Answer 1

As I said in my comment you cannot use a CommandBuilder when you use a join. You need to supply your own Update, Insert, and Delete commands for the DataAdapter. Be sure to use the overload of the Parameters.Add method that includes the name of the source column. This provides the mapping for the DataAdapter. I used a database on my machine to show the code. You would probably want to add commands for Insert and Delete.
Private da As SqlDataAdapter
Private Sub Button3_Click(sender As Object, e As EventArgs) Handles Button3.Click
da = New SqlDataAdapter
Dim dt As New DataTable
Dim query = "Select Article.ArticleID, Article.Title, Author.LastName From Article Inner Join Author on Article.AuthorID = Author.AuthorID"
Using cn As New SqlConnection(My.Settings.PublishersConnection)
Using cmd As New SqlCommand(query, cn)
da.SelectCommand = cmd
da.Fill(dt)
End Using
End Using
DataGridView1.DataSource = dt
End Sub
Private Sub Button4_Click(sender As Object, e As EventArgs) Handles Button4.Click
Dim Uquery = "Update Article Set Title = #Title Where ArticleID = #ID;"
Dim dt As DataTable = CType(DataGridView1.DataSource, DataTable)
Using cn As New SqlConnection(My.Settings.PublishersConnection)
Using UCommand As New SqlCommand(Uquery, cn)
UCommand.Parameters.Add("#Title", SqlDbType.VarChar, 50, "Title")
UCommand.Parameters.Add("#ID", SqlDbType.Int, 4, "ArticleID")
da.UpdateCommand = UCommand
da.Update(dt)
End Using
End Using
End Sub