How do I create a countdown timer using Hours, Minutes and Seconds? - vb.net

Question

I was wondering how I would go about fixing my countdown timer so that it shows the time in Hours:Minutes:Seconds?
currently, it only outputs the seconds and I'm not sure where I have gone wrong.
Any help is much appreciated.
Code:
Public Class Form1
Dim TargetDT As DateTime
Dim fields() As String
Dim Days, Hours, minutes, seconds, milliseconds As String
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
fields = Split(TextBox1.Text, ":")
Hours = fields(0)
minutes = fields(1)
seconds = fields(2)
Dim CountDownFrom As TimeSpan = TimeSpan.FromHours(Hours).FromMinutes(minutes).FromSeconds(seconds)
Timer1.Interval = 1000
TargetDT = DateTime.Now.Add(CountDownFrom)
Timer1.Enabled = True
End Sub
Private Sub Timer1_Tick(sender As Object, e As System.EventArgs) Handles Timer1.Tick
Dim ts As TimeSpan = TargetDT.Subtract(DateTime.Now)
If ts.TotalMilliseconds > 0 Then
Con1Time.Text = ts.ToString("hh\:mm\:ss")
Else
Con1Time.Text = "0:00:00"
Timer1.Stop()
MessageBox.Show("Done")
End If
End Sub
End Class

Answer 1

Start by assigning the time you want to countdown to a TimeSpan field. When you want to star counting down, call Start on a Timer and a Stopwatch. In the Tick event handler of the Timer, get the Elapsed of the Stopwatch and subtract that from the original time to get the time remaining as a TimeSpan. You can then format and display that. When that time remaining reaches zero, the countdown has expired.
Private countDownTime As TimeSpan
Private countDownWatch As Stopwatch
Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
countDownTime = TimeSpan.FromMinutes(30)
countDownWatch = Stopwatch.StartNew()
Timer1.Start()
End Sub
Private Sub Timer1_Tick(sender As Object, e As EventArgs) Handles Timer1.Tick
Dim timeRemaining = countDownTime - countDownWatch.Elapsed
If timeRemaining < TimeSpan.Zero Then
timeRemaining = TimeSpan.Zero
End If
Label1.Text = timeRemaining.ToString("hh\:mm\:ss")
If timeRemaining = TimeSpan.Zero Then
Timer1.Stop()
MessageBox.Show("Countdown complete")
End If
End Sub
That said, your specific issue is here:
Dim CountDownFrom As TimeSpan = TimeSpan.FromHours(Hours).FromMinutes(minutes).FromSeconds(seconds)
That does not do what you think it does. You're only getting the result of the FromSeconds call. If you want to create a TimeSpan with hours, minutes and seconds then call the appropriate constructor
Dim CountDownFrom As TimeSpan = New TimeSpan(Hours, minutes, seconds)
Of course, those arguments should be Integer values, not Strings. Turn Option Strict On and use the proper data types.