Vb.net ArgumentNullException when removing from dictionary - vb.net

Question

I'm having an issue where I'm trying to delete an element from my dictionary at the selected index in a listbox. I added 3 elements to a SortedDictionary and printing them into a list box. I'm trying to delete the item from the dictionary that is highlighted in the listbox, however when I click remove I get the System.ArgumentNullException: 'Value cannot be null. Parameter name: key' within my Sub btnDeleteLibrary_Click Why is this?
Error occurs at the line Libraries.Remove(lstLibraries.SelectedValue)
Public Class frmManager
Dim Libraries As New SortedDictionary(Of String, String)
Private Sub frmManager_Load(sender As Object, e As EventArgs) Handles Me.Load
Libraries.Add("Zahnow Library", "SVSU")
Libraries.Add("Fleschner Memorial Library", "BR")
Libraries.Add("Scott D. James Technical Repository", "SDJ")
lstLibraries.Items.Clear()
populatelstLibrary()
End Sub
Sub populatelstLibrary()
For Each library In Libraries
lstLibraries.Items.Add(vbCrLf & library.Key & " --- " & library.Value)
Next
End Sub
Private Sub btnDeleteLibrary_Click(sender As Object, e As EventArgs) Handles btnDeleteLibrary.Click
Libraries.Remove(lstLibraries.SelectedValue)
lstLibraries.Items.Clear()
populatelstLibrary()
End Sub
End Class

Answer 1

Since you are constructing a custom display string for your ListBox items it makes it harder to map that directly to the dictionary.
The easiest solution would be to create a custom class that you store in the ListBox and set the ListBox's DisplayMember and ValueMember properties, telling it how to display each item as well as which property it should get from an item when you call SelectedValue.
Class:
Public Class LibraryItem
Public Property Name As String
Public Property Code As String
Public ReadOnly Property DisplayName As String
Get
Return vbCrLf & Me.Name & " --- " & Me.Code
End Get
End Property
Public Sub New()
End Sub
Public Sub New(ByVal Name As String, ByVal Code As String)
Me.Name = Name
Me.Code = Code
End Sub
End Class
Initial setup:
Private Sub frmManager_Load(sender As Object, e As EventArgs) Handles Me.Load
'Tell the ListBox which properties to use for display and value.
lstLibraries.DisplayMember = "DisplayName"
lstLibraries.ValueMember = "Name"
'Your code...
End Sub
Filling the ListBox:
Sub populatelstLibrary()
For Each library In Libraries
lstLibraries.Items.Add(New LibraryItem(library.Key, library.Value))
Next
End Sub
Now SelectedValue will get you the value of the selected item's Name property, which corresponds to the key in the dictionary.

Answer 2

I would change some things in your code. First it seems that you have your sorted dictionary built with the wrong values for Key and Value, change it to
Libraries.Add("SVSU","Zahnow Library")
Libraries.Add("BR", "Fleschner Memorial Library")
Libraries.Add("SDJ", "Scott D. James Technical Repository")
' and call immediately
populatelstLibrary()
Now in populatelstLibrary change the code to
Sub populatelstLibrary()
lstLibraries.DataSource = Nothing
lstLibraries.DisplayMember = "Value"
lstLibraries.ValueMember = "Key"
lstLibraries.DataSource = Libraries.ToList()
End Sub
finally in the button click just check for null and remove the SelectedValue
Private Sub btnDeleteLibrary_Click(sender As Object, e As EventArgs) Handles btnDeleteLibrary.Click
If lstLibraries.SelectedValue IsNot Nothing Then
Libraries.Remove(lstLibraries.SelectedValue)
populatelstLibrary()
End If
End Sub