How do I reset numbering in tables? - sql

Question

I have some data that I have been working with. With that, I have been deleting records on-the-fly. Now that I have a working data model, I want to re-start my auto-numbering. How do I reset my existing data to adhere to an auto-formatting starting from 1....n?
I have tried to do a Compact and Repair but that didn't seem to fix the issue.
For reference, my table looks like this:
R-002
R-054
R-123
R-057
R-061
I would like to get them back to:
R-001
R-002
R-003
R-004
R-005
And for each subsequent entry added, adhere to this new auto-numbering so the next record, for example, will be R-006.
Writing an UPDATE query works for immediate fixing but it doesn't address the adherence to the auto-numbering for future entries.
I would think there is an elegant way to do this. The data in my tables are part of Relationships so it makes it a little tricky.
If anyone has any tips / recommendations, I would appreciate it.

Answer 1

What you need is sequential numbering of the records.
I wrote an article on the various methods for doing this:
Sequential Rows in Microsoft Access
One is to add row numbers:
' Builds consecutive row numbers in a select, append, or create query
' with the option of a initial automatic reset.
' Optionally, a grouping key can be passed to reset the row count
' for every group key.
'
' 2018-08-23. Gustav Brock, Cactus Data ApS, CPH.
'
Public Function RowNumber( _
ByVal Key As String, _
Optional ByVal GroupKey As String, _
Optional ByVal Reset As Boolean) _
As Long
' Uncommon character string to assemble GroupKey and Key as a compound key.
Const KeySeparator As String = "¤§¤"
' Expected error codes to accept.
Const CannotAddKey As Long = 457
Const CannotRemoveKey As Long = 5
Static Keys As New Collection
Static GroupKeys As New Collection
Dim Count As Long
Dim CompoundKey As String
On Error GoTo Err_RowNumber
If Reset = True Then
' Erase the collection of keys and group key counts.
Set Keys = Nothing
Set GroupKeys = Nothing
Else
' Create a compound key to uniquely identify GroupKey and its Key.
' Note: If GroupKey is not used, only one element will be added.
CompoundKey = GroupKey & KeySeparator & Key
Count = Keys(CompoundKey)
If Count = 0 Then
' This record has not been enumerated.
'
' Will either fail if the group key is new, leaving Count as zero,
' or retrieve the count of already enumerated records with this group key.
Count = GroupKeys(GroupKey) + 1
If Count > 0 Then
' The group key has been recorded.
' Remove it to allow it to be recreated holding the new count.
GroupKeys.Remove (GroupKey)
Else
' This record is the first having this group key.
' Thus, the count is 1.
Count = 1
End If
' (Re)create the group key item with the value of the count of keys.
GroupKeys.Add Count, GroupKey
End If
' Add the key and its enumeration.
' This will be:
' Using no group key: Relative to the full recordset.
' Using a group key: Relative to the group key.
' Will fail if the key already has been created.
Keys.Add Count, CompoundKey
End If
' Return the key value as this is the row counter.
RowNumber = Count
Exit_RowNumber:
Exit Function
Err_RowNumber:
Select Case Err
Case CannotAddKey
' Key is present, thus cannot be added again.
Resume Next
Case CannotRemoveKey
' GroupKey is not present, thus cannot be removed.
Resume Next
Case Else
' Some other error. Ignore.
Resume Exit_RowNumber
End Select
End Function
These you could format as you like, for example:
RNumber: "R-" & Format([RwoNumber], "000")