ActiveDocument error 4248 in Ribbon onLoad sub - vba

Question

I have a global template with a customized ribbon. When I try to open a document, I receive error 4248, which claims the command can't run because no document is open.
The code in the onLoad sub is checking to make sure that the active document isn't the template or Normal.dotm because I don't want document variables written to those files via the called procedures. This worked fine in Word 2013, but I'm noticing that in Word 2016, it seems the ribbon onLoad procedure is running before a document in Word is open.
I've pinpointed the issue to the ActiveDocument.Name line, where I can trap the error and resume next, but that doesn't help me run the additional code after the determination is made that this isn't the global template document or Normal.dotm.
Public myRibbonNewNormal As IRibbonUI
Public bVisible As Boolean
Dim bDocSaved As Boolean
Sub onLoad_newNormal(ribbon As IRibbonUI)
Set myRibbonNewNormal = ribbon
On Error GoTo onLoadError
If ActiveDocument.Name = "Styles.dotm" Or ActiveDocument.Name =
"newNormal.dotm" Then
Exit Sub
ElseIf ActiveDocument.ReadOnly Then
Exit Sub
Else
'Call checkDocType
Call uncheckUpdateStyles
Call removeClientFooter
Call checkTemplate
If bDocSaved <> True Then
Call preventSave
Else
'do nothing
End If
End If
Exit Sub
onLoadError:
If Err.Number = 0 Then
Resume Next
ElseIf Err.Number = 5 Then
Resume Next
ElseIf Err.Number = 5825 Then
Resume Next
ElseIf Err.Number = 5903 Then
Resume Next
'ElseIf Err.Number = 5155 Then
' Resume Next
ElseIf Err.Number = 4248 Then
Resume Next
Else
MsgBox "This error is in the onLoad sub in the newNormal RibbonControl" _
& vbCrLf & vbCfLf & "Error: " & Err.Number & vbCrLf & Err.Description, ,
"Error"
End If
End Sub
(Please excuse my error handling. I was in a hurry when I wrote this code and just haven't gotten back around to doing it properly.)
Is there a way for me to wait to execute the onLoad sub until Word has opened the document (by simple double-click)? I'm sure I'm missing something here, but I'm struggling to find any information about this online.

Answer 1

Move the code to an application level event handler. The code will run each time a new document is opened, but that can be remedied if needed (see code comments).
Create a new class module and name the class module EventMngr.
Place the following code in the class module:
Public WithEvents appevent As Application
Private Sub appevent_DocumentOpen(ByVal Doc As Document)
'This code will only allow the event to fire once
Static hasOpened As Boolean
If hasOpened Then Exit Sub Else hasOpened = True
'Place Code Here...
End Sub
Then you can place this line in a normal module before any other subs/functions
'application level event handler
Public myEventHandler As New EventMngr
And last, place this in your Ribbon OnLoad sub:
'application event handler
Set myEventHandler.appevent = Application

Answer 2

Similar to the previous answer but possibly simpler is to add autoopen and autonew procedures to your code and capture the activedocument in those procedures rather than the onload procedure.