The instance variable super cannot be accessed from the definition of another instance variable - oop

Question

i'm trying to do some OOP in OCAML.
Here are two classes :
class virtual game_object id x y z =
object (self)
val id : int = id
val x : int = x
val y : int = y
val z : int = z
method get_x = x
method get_y = y
method get_z = z
end;;
class tile id x y z tile_type =
object(self)
inherit game_object id x y z as super
val tile_type : tile_type = tile_type
val w : int = 80
val h : int = 80
val box : Sdl.rect = Sdl.Rect.create super#get_x super#get_y w h (* This line triggers the error *)
method get_tile_type = tile_type
end
;;
When I try to compile, I get this error :
The instance variable super cannot be accessed from the definition of another instance variable
I have no idea how to solve this issue. Please help? Thank you.

Answer 1

The simplest solution might be to factorize the common part of the value instance, avoid the getter of the super class, and just define the rectangle from the class arguments:
class tile id x y z tile_type =
let w = 80 in
let h = 80 in
object(self)
val box = Sdl.Rect.create x y w h
inherit game_object id x y z as super
val tile_type : tile_type = tile_type
val w = w
val h = h
method get_tile_type = tile_type
end
If you need to access x and y through the getters, you could make rect mutable, initialize it to a dummy value first, and then add an initializer to set it to the correct value:
class tile id x y z tile_type =
object(self)
inherit game_object id x y z as super
val tile_type : tile_type = tile_type
val w = 80
val h = 80
val mutable box = Sdl.Rect.create 0 0 0 0
initializer box <- Sdl.Rect.create super#get_x super#get_y w h
method get_tile_type = tile_type
end