I'm having difficulty calculating time differences in Visual Basic [closed] - vb.net

Question

Closed. This question is not reproducible or was caused by typos. It is not currently accepting answers.
This question was caused by a typo or a problem that can no longer be reproduced. While similar questions may be on-topic here, this one was resolved in a way less likely to help future readers.
Closed 4 years ago.
Improve this question
Layout of Calculator
I am trying to build a program that calculates times differences in minutes. I do this by subtracting the start time from the finish time. I have four text boxes, two of which are for the time unit of hours (h), and the other two are for minutes (m).
a is the starting time in hours and c is the finish time in hours. They are being multiplied by 60 to convert the hours to minutes. I want to calculate the time difference between 5:40pm and 7:15pm but some how end up with 567 when the answer should be 95.
This is not a homework task, I'm a lazy learner driver in Australia who wants to create a simple program that calculates the time of a journey in minutes.
Can somebody please tell me what I'm doing wrong?
Here is my code:
Public Class Calc
Dim Product
Dim a, b, c, d As Integer
Private Sub Enter_Click(sender As Object, e As EventArgs) Handles Enter.Click
a = Val(TextBox1.Text) * 60
b = Val(TextBox2.Text)
c = Val(TextBox3.Text) * 60
d = Val(TextBox4.Text)
Product = (c - a + d - b)
Time.Text = ("Driving Time: " & Product)
End Sub
End Class

Answer 1

I wasn't going to post this but I couldn't let the use of TimeSerial by Dy.Lee go unanswered. This code uses reasonable variable names, uses the correct type for time periods, i.e. TimeSpan, and also compiles with Option Strict On, which it should pretty much always be. I'd get rid of that Val usage too but I couldn't be bothered here.
Private Sub Enter_Click(sender As Object, e As EventArgs) Handles Enter.Click
Dim startHours = CInt(Val(TextBox1.Text))
Dim startMinutes = CInt(Val(TextBox2.Text))
Dim endHours = CInt(Val(TextBox3.Text))
Dim endMinutes = CInt(Val(TextBox4.Text))
Dim startTime As New TimeSpan(startHours, startMinutes, 0)
Dim endTime As New TimeSpan(endHours, endMinutes, 0)
Dim timeDifference = endTime - startTime
Time.Text = ("Driving Time: " & timeDifference.TotalMinutes)
End Sub
EDIT: It also declares variables in the appropriate place, i.e. in the method they're being used in. If you're using those same variables elsewhere then you'd have to stick with fields but I'm guessing that you're not doing so.
EDIT: Here's a version without the dodgy Val calls and some proper validation. You could combine all the If statements into one but separating them allows you to display different messages based on the type of issue.
Private Sub Enter_Click(sender As Object, e As EventArgs) Handles Enter.Click
Dim startHours As Integer
Dim startMinutes As Integer
Dim endHours As Integer
Dim endMinutes As Integer
If Integer.TryParse(TextBox1.Text, startHours) AndAlso
Integer.TryParse(TextBox2.Text, startMinutes) AndAlso
Integer.TryParse(TextBox3.Text, endHours) AndAlso
Integer.TryParse(TextBox4.Text, endMinutes) Then
If startHours < 24 AndAlso
startMinutes < 60 AndAlso
endHours < 24 AndAlso
endMinutes < 60 Then
Dim startTime As New TimeSpan(startHours, startMinutes, 0)
Dim endTime As New TimeSpan(endHours, endMinutes, 0)
If startTime < endTime Then
Dim timeDifference = endTime - startTime
Time.Text = ("Driving Time: " & timeDifference.TotalMinutes)
Else
'Notify user of invalid input.
End If
Else
'Notify user of invalid input.
End If
Else
'Notify user of invalid input.
End If
End Sub

Answer 2

#PaulHebert pointed out to me that I needed to swap around textbox 3 & 4 because I was treating the wrong fields as hours. The math had made sense in my head so I probably overlooked a rather simple yet inconvenient mistake. I want to thank everyone who tried to help :) Merry Christmas!

Answer 3

Your math is wrong you are subtracting the hours and then adding them to the difference of minutes. You need to get the total number of minutes since midnight from each time and then subtract those. Then get the absolute value so you don't have negative minutes
Private Sub Enter_Click(sender As Object, e As EventArgs) Handles Enter.Click
a = Val(TextBox1.Text) * 60
b = Val(TextBox2.Text)
c = Val(TextBox3.Text) * 60
d = Val(TextBox4.Text)
Product = Math.Abs((c +d) - (a + b))
Time.Text = ("Driving Time: " & Product)
End Sub

Answer 4

Try using this code
Private Sub Enter_Click(sender As Object, e As EventArgs) Handles
a = CInt(Trim(TextBox1.Text)) * 60
b = CInt(Trim(TextBox2.Text))
c = CInt (Trim(TextBox3.Text)) * 60
d = CInt(Trim(TextBox4.Text))
Product = (c + d) - (a + b)
Time.Text = ( "Driving Time: " & Product)
End Sub
Also make sure that the text boxes are properly arranged. Text box 1 should come first followed by the others.