VB.NET ContextMenuStrip dynamic subitems. How to add event on each subitems? - vb.net

Question

how can I add an event or get the text of the subitem of the contextmenustrip control after I clicked the subitem?
Here's my code:
Try
enrollment_conn.Open()
command = New SqlCommand("SELECT DISTINCT Section FROM dbo.Enrollees WHERE Grade = '" & Main.Enrollees_Cbx_grade.Text & "' AND Strand = '" & Main.Enrollees_Cbx_strand.Text & "' AND School_Year = '" & Main.Enrollees_Cbx_sy.Text & "' AND Enrolled = 'Yes'", enrollment_conn)
reader = command.ExecuteReader
Main.Enrollees_CMS_enrolleesList.Items.Clear()
Dim tm = New ToolStripMenuItem("Filter")
Main.Enrollees_CMS_enrolleesList.Items.Add(tm)
While reader.Read
tm.DropDownItems.Add(reader.Item("Section").ToString)
End While
enrollment_conn.Close()
Catch ex As Exception
MsgBox(ex.Message, vbExclamation)
End Try
The code above adds a Toolstripitem called Filter and when I right click my datagridview. The item Filter shows and has subitems which I added by using a query. The question is how can I get the text or add an event to the subitems? Thanks.

Answer 1

The Add method that you're using here is overloaded:
tm.DropDownItems.Add(reader.Item("Section").ToString)
You should use the overload that lets you specify a Click event handler:
tm.DropDownItems.Add(reader.Item("Section").ToString, Nothing, AddressOf MenuItem_Click)
The third argument is a delegate to the event handler method. If you're not comfortable writing that from scratch yourself, the simplest option is to let the IDE create one for you. Simply double-click a menu item in the designer and an event handler will be generated in the usual way. You can then delete the Handles clause from the end of the declaration and change the name to something more generic. You can then access the menu item that was clicked via the sender parameter, which is always a reference to the object that raised the event:
Private Sub MenuItem_Click(sender As Object, e As EventArgs)
Dim menuItem = DirectCast(sender, ToolStripMenuItem)
'Use menuItem here.
End Sub
If you need data for each menu item then you can assign it to the Tag property when you create it, e.g.
tm.DropDownItems.Add(reader.Item("Section").ToString,
Nothing,
AddressOf MenuItem_Click).Tag = reader.Item("Data")
and then get it back again in the event handler:
Private Sub MenuItem_Click(sender As Object, e As EventArgs)
Dim menuItem = DirectCast(sender, ToolStripMenuItem)
Dim data = menuItem.Tag
'Use data here.
End Sub