Delete text enclosed in square brackets from a string - vba

Question

I have records that include text between square brackets.
aaaaaa[aaaaa]
I need to erase that text, square brackets included.
The result would be:
aaaaaa
I'm trying this code:
Dim sqr as Integer
Dim origin as String
Dim result as String
InStr(origin,[)
I can find the first square bracket, but it does not do the job.

Answer 1

Since in your question you state that you wish to remove text within square brackets (including removing the brackets), I would suggest the following:
Function RemoveSqBracketText(strStr As String) As String
Dim lngId1 As Long
Dim lngId2 As Long
lngId1 = InStr(strStr, "[")
lngId2 = InStr(strStr, "]")
If lngId1 > 0 And lngId2 > 0 Then
RemoveSqBracketText = Left(strStr, lngId1 - 1) & RemoveSqBracketText(Mid(strStr, lngId2 + 1))
Else
RemoveSqBracketText = strStr
End If
End Function
This will recursively remove all instances of text enclosed in square brackets, and assumes that you only wish to remove text if it is enclosed within an opening and closing bracket.
Examples:
?RemoveSqBracketText("abc[123]")
abc
?RemoveSqBracketText("abc[123]def[ghi]")
abcdef
?RemoveSqBracketText("abc[123]defghi]")
abcdefghi]

Answer 2

You need to work out the index of the opening square bracket - InStr(origin, "[") (note the double quotes) is a good start.
Now you can loop from that index up to the end of the string, using the Mid$ function to inspect the character at the current index, until the closing bracket is located:
Dim currentPosition As Long
currentPosition = InStr(origin, "[")
If currentPosition = 0 Then
' no opening bracket. now what?
Else
Dim bracketedWord As String
For currentPosition = currentPosition + 1 To Len(origin)
If Mid$(origin, currentPosition, 1) <> "]" Then
bracketedWord = bracketedWord & Mid$(origin, currentPosition, 1)
Else
'found the closing bracket: we're done.
Exit For
End If
Next
End If
Or, you can use InStr to locate the [ opening brace and the closing brace ] positions, then compute the length of the substring between these two positions, and use the Mid$ function to pull the substring without looping.
Alternatively, with a reference to Microsoft VBScript Regular Expressions 5.5 you could use a simple regular expression:
Public Function FindBracketedWord(ByVal value As String) As String
Dim regex As RegExp
Set regex = new RegExp
regex.Pattern = "\[(\w+)\]" ' matches a square-bracketed "word", no spaces
Dim matches As MatchCollection
Set matches = regex.Execute(value)
If matches.Count <> 0 Then result = matches(0).SubMatches(0)
FindBracketedWord = result
End Function