Create a key comparing two rows in SAS - sql

Question

I have SAS data set which has 2 columns
Var1 Var2
A B
B C
C D
D E
F G
H F
Can i create a same unique key for above rows. The final output which i want is
Var1 Var2 Key
A B 1
B C 1
C D 1
D E 1
F G 2
H F 2

Answer 1

The general problem of assigning a group identifier based on row-to-row linkages can be very rich and difficult. However, for the sequential case the solution is not so bad.
Sample code
Presume the group identity changes when both variable values are not present in the prior row.
data have;input
Var1 $ Var2 $;datalines;
A B
B C
C D
D E
F G
H F
run;
data want;
set have;
group_id + ( var1 ne lag(var2) AND var2 ne lag(var1) );
run;
Complex case
#Vivek Gupta states in comments
There are random arrangement of rows in the dataset
Consider arbitrary rows p and q with items X and Y. Groups are created by linkages whose criteria is:
p.X = q.X
OR p.X = q.Y
OR p.y = q.x
OR p.y = q.y
A hash based solver will populate groups initially from a data scan. Repeated scans of data with hash lookups migrate items into lower groups (thus enlarging the group) until there is a scan with no migrations.
data pairs;
id + 1;
input item1 $ item2 $ ;
cards;
A B
C D
D E
B C
H F
X Y
F G
run;
data _null_ ;
length item $8 group 8;
retain item '' group .;
if 0 then set pairs;
declare hash pairs();
pairs.defineKey('item1', 'item2');
pairs.defineDone();
declare hash map(ordered:'A');
map.definekey ('item');
map.definedata ('item', 'group');
map.definedone();
_groupId = 0;
noMappings = 0;
nPass = 0;
do until (end);
set pairs end=end;
pairs.replace();
found1 = map.find(key:item1) eq 0; item1g = group;
found2 = map.find(key:item2) eq 0; item2g = group;
put item1= item2= found1= found2= item1g= item2=;
select;
when ( found1 and not found2) map.add(key:item2,data:item2,data:item1g);
when (not found1 and found2) map.add(key:item1,data:item1,data:item2g);
when (not found1 and not found2) do;
_groupId + 1;
map.add(key:item1,data:item1,data:_groupId);
map.add(key:item2,data:item2,data:_groupId);
end;
otherwise
;
end;
end;
declare hiter data('pairs');
do iteration = 1 to 1000 until (discrete);
put iteration=;
discrete = 1;
do index = 1 by 1 while (data.next() = 0);
found1 = map.find(key:item1) eq 0; item1g = group;
found2 = map.find(key:item2) eq 0; item2g = group;
put index= item1= item2= item1g= item2g=;
if (item1g < item2g) then do; map.replace(key:item2,data:item2,data:item1g); discrete=0; end;
if (item2g < item1g) then do; map.replace(key:item1,data:item1,data:item2g); discrete=0; end;
end;
end;
if discrete then put 'NOTE: discrete groups at' iteration=; else put 'NOTE: Groups not discrete after ' iteration=;
map.output(dataset:'map');
run;
Complex case #2
Groups are created by linkages whose criteria is
p.X = q.X
OR p.y = q.y
The following example is offsite and too long to post here.
How to create groups from rows associated by linkages in either of two variables
General statement of problem:
Given: P = p{i} = (p{i,1),p{i,2}), a set of pairs (key1, key2).
Find: The distinct groups, G = g{x}, of P,
such that each pair p in a group g has this property:
key1 matches key1 of any other pair in g.
-or-
key2 matches key2 of any other pair in g.
In short, the example shows
An iterative way using hashes.
Two hashes maintain the groupId assigned to each key value.
Two additional hashes are used to maintain group mapping paths.
When the data can be passed without causing a mapping, then the groups
have been fully determined.
A final pass is done
groupIds are assigned to each pair
data is output to a table

Answer 2

As you have not describe any logic so for your sample output below query will work
select Var1, Var2, 1 as [key]
from t