Differentiate between entering 0 and pressing cancel in application.inputbox - vba

Question

I have a macro which takes a value from Application.InputBox and then tries to ensure that a numerical value has been put into it, and that cancel has not been pressed.
Sub test()
Dim testvalue As Variant
testvalue = Application.InputBox(Prompt:="Whatever", Title:="Whatever", Default:=10, Type:=1)
If testvalue <> False Then
MsgBox ("Test != False")
Else
MsgBox ("Test = False")
End If
If VarType(testvalue) = vbInteger Or VarType(testvalue) = vbLong Then
MsgBox ("Numerical value")
Else
MsgBox ("Nonnumerical value")
End If
End Sub
However, it seems to have trouble differentiating between having 0 put into the InputBox and cancel being pressed. In both cases, the if-statements will return that Test = False and that Test is a nonnumerical value. To be fair, the second if-statements does the same for other integers as well, but I thought there might be some small chance of differentiating between integers stored in the variant and a boolean value stored in it using the VarType method.
Is there any way to differentiate between 0 and cancel being the return-value for the inputbox, or will I have to make my own custom form?
Trying to use VBA's InputBox as suggested in the comments returns "String", no matter what value is entered into it, or what button is pressed:
Sub test2()
Dim testvalue As Variant
testvalue = InputBox("Test")
Select Case VarType(testvalue)
Case vbBoolean:
Debug.Print "Boolean"
Case vbInteger:
Debug.Print "Integer"
Case vbLong:
Debug.Print "Long"
Case vbString:
Debug.Print "String"
Case vbVariant:
Debug.Print "Variant"
End Select
End Sub

Answer 1

Apparently double is a numerical type as well >_> Chalk this one up to me being stupid, checking for the wrong thing, and making the wrong assumptions. Thanks to rory in the comments for getting me to check further on what types the various functions returned.
To be more explicit, when a numerical value is entered into Application.InputBox, it returns a Double, so that is what I should check for when wanting to ensure a numerical value.

Answer 2

Instead of VarType you can use StrPtr which will only give 0 if the input box was cancelled, although I'm not sure how it reacts to Application.InputBox(). If you are using just the standard InputBox() however it works perfectly, therefore to detect a cancelled InputBox you would add this into your code:
If StrPtr(testvalue) = 0 Then
Call MsgBox("Input cancelled.", "Cancelled")
End If
*Something to be aware of when using this method is that it relies on buggy behaviour in InputBox. Microsoft aren't going to fix it as it would break a lot of people's code but it is something to take note of.

Answer 3

You could adjust your type to 1+4 and check for the Vartype
Sub test()
Dim testvalue As Variant
testvalue = Application.InputBox(Prompt:="Whatever", Title:="Whatever", Default:=10, Type:=5)
If VarType(testvalue) <> vbBoolean Then
MsgBox ("Test != False")
Else
MsgBox ("Test = False")
End If
End Sub