Screen capture of a particular instance of multiple application windows - vb.net

Question

I need to screen capture a particular window of a multi-window application.
A good example: I run OUTLOOK with two windows - Mail and Calendar.
When I use Process.GetProcessesByName(ApplicationToWatch).FirstOrDefault() I of course get the "first" window. How do I get access to the "second" or subsequent windows? (Interesting that there is a FirstOrDefault but not another method to get something else - I'm clearly missing something).

Answer 1

You already have some indications on how to get a child window Handle using EnumChildWindows, to be associated with GetClassName.
So I'll propose you another method, using UI Automation.
It's probably not so well known, but in this case it's quite straightforward and it can simplify this task.
You just need to know the Handle of the Main Window whose child you want to enumerate and filter the collection (AutomationElementCollection) of child windows using LINQ's .Where() or .FirstOrDefault() methods.
As a note, the UI Automation enumeration is not as thorough as EnumChildWindows. Also, the returned Class Names can be different, in some cases, from the actual class name of specific UI Elements.
But those are, possibly, UI Elements your not interested in.
To get the Handle of the Outlook main window, we use Process.GetProcessesByName() as usual.
The Automation Element is then aquired using the AutomationElement.FromHandle() method.
To find specific child Elements, we can use this Main Automation Element (source reference) .FindAll() method, filtering the returned collection, if needed, with .Where() - to define a sub-collection - or .FirstOrDefault(), to get the reference of a specific Element Class or Handle (or other known details).
These methods show how to take a screenshot of Outlook's side Calendar panel and the Main Calendar window.
Use the code already discussed in your previous question to take the actual screenshot of the selected Screen bounds.
This code requires to add a reference to: UIAutomationClient
UIAutomationTypes WindowsBase
Imports System.Diagnostics
Imports System.Drawing
Imports System.Windows.Automation
Dim OutLookProc As Process = Process.GetProcessesByName("OUTLOOK").FirstOrDefault()
Dim MainElement As AutomationElement = AutomationElement.FromHandle(OutLookProc.MainWindowHandle)
Dim SmallCalendar As AutomationElement =
MainElement.FindAll(TreeScope.Subtree, Automation.RawViewCondition).
OfType(Of AutomationElement)().
FirstOrDefault(Function(elm) elm.Current.Name.Contains("NUIDocument") AndAlso
(Not String.IsNullOrEmpty(elm.Current.AutomationId)))
Dim CalendarNavigator As AutomationElement =
MainElement.FindAll(TreeScope.Subtree, Automation.RawViewCondition).
OfType(Of AutomationElement)().
FirstOrDefault(Function(elm) elm.Current.ClassName.Contains("TreeDisplayNode"))
If SmallCalendar IsNot Nothing Then
Dim SmallCalendarHeight As Integer = CInt(CalendarNavigator.Current.BoundingRectangle.Y -
SmallCalendar.Current.BoundingRectangle.Y)
Dim CalLocation As Point = New Point(CInt(SmallCalendar.Current.BoundingRectangle.Location.X),
CInt(SmallCalendar.Current.BoundingRectangle.Location.Y))
Dim CalSize As Size = New Size(CInt(SmallCalendar.Current.BoundingRectangle.Width), SmallCalendarHeight)
Dim SmallCalendarBounds As Rectangle = New Rectangle(CalLocation, CalSize)
SmallCalendarBounds.Inflate(-20, 0)
'CopyFormScreen() the SmallCalendarBounds rectangle. Inflate as needed
End If
This part of the code calculates the Screen bounds of Outlook's side Calendar object.
It may not be that useful, but it's a way to show how you can use these classes to parse/inspect the UI Elements of a process Main Window.
This is the result:
The Main Calendar window is simpler to identify and capture.
All Calendars classes names end with ViewWnd, thus, no matter which one is selected/in use, you will always be able to identify it quite easily.
Dim LargeCalendar As AutomationElement =
MainElement.FindAll(TreeScope.Descendants, Automation.RawViewCondition).
OfType(Of AutomationElement)().
FirstOrDefault(Function(elm) elm.Current.ClassName.Contains("ViewWnd"))
If LargeCalendar IsNot Nothing Then
Dim LCalLocation As Point = New Point(CInt(LargeCalendar.Current.BoundingRectangle.Location.X),
CInt(LargeCalendar.Current.BoundingRectangle.Location.Y))
Dim LCalSize As Size = New Size(CInt(LargeCalendar.Current.BoundingRectangle.Width),
CInt(LargeCalendar.Current.BoundingRectangle.Height))
Dim LargeCalendarBounds As Rectangle = New Rectangle(LCalLocation, LCalSize)
End If
This is the result:

Answer 2

This should help:
getting the window position:
How to get and set the window position of another application in C#
getting the window handle:
Get Application's Window Handles
bringing another application into the front:
https://social.msdn.microsoft.com/Forums/en-US/b5a91ac4-4894-45a1-aa66-b4d548ca8163/bring-another-application-to-front?forum=winforms
you could try those tricks and just copy from screen.